NAME

zshall - the Z shell meta-man page

OVERVIEW

Because zsh contains many features, the zsh manual has been split into a number of sections. This manual page includes all the separate manual pages in the following order:

zsh Zsh overview

zshroadmap Informal introduction to the manual

zshmisc Anything not fitting into the other sections

zshexpn Zsh command and parameter expansion

zshparam Zsh parameters

zshoptions Zsh options

zshbuiltins Zsh built-in functions

zshzle Zsh command line editing

zshcompwid Zsh completion widgets

zshcompsys Zsh completion system

zshcompctl Zsh completion control

zshmodules Zsh loadable modules

zshcalsys Zsh built-in calendar functions

zshtcpsys Zsh built-in TCP functions

zshzftpsys Zsh built-in FTP client

zshcontrib Additional zsh functions and utilities

DESCRIPTION

Zsh is a UNIX command interpreter (shell) usable as an interactive login shell and as a shell script command processor. Of the standard shells, zsh most closely resembles ksh but includes many enhancements. It does not provide compatibility with POSIX or other shells in its default operating mode: see the section `Compatibility' below.

Zsh has command line editing, builtin spelling correction, programmable command completion, shell functions (with autoloading), a history mechanism, and a host of other features.

AUTHOR

Zsh was originally written by Paul Falstad. Zsh is now maintained by the members of the zsh-workers mailing list <zsh-workers@zsh.org>. The development is currently coordinated by Peter Stephenson <pws@zsh.org>. The coordinator can be contacted at <coordinator@zsh.org>, but matters relating to the code should generally go to the mailing list.

AVAILABILITY

Zsh is available from the following HTTP and anonymous FTP site.

ftp://ftp.zsh.org/pub/
https://www.zsh.org/pub/

The up-to-date source code is available via Git from Sourceforge. See https://sourceforge.net/projects/zsh/ for details. A summary of instructions for the archive can be found at https://zsh.sourceforge.io/.

MAILING LISTS

Zsh has several mailing lists:

<zsh-announce@zsh.org>

Announcements about releases, major changes in the shell and the monthly posting of the Zsh FAQ. (moderated)

<zsh-users@zsh.org>

User discussions.

<zsh-workers@zsh.org>

Hacking, development, bug reports and patches.

<zsh-security@zsh.org>

Private mailing list (the general public cannot subscribe to it) for discussing bug reports with security implications, i.e., potential vulnerabilities.

To subscribe or unsubscribe, send mail to the associated administrative address for the mailing list.

<zsh-announce-subscribe@zsh.org>

<zsh-users-subscribe@zsh.org>

<zsh-workers-subscribe@zsh.org>

<zsh-announce-unsubscribe@zsh.org>

<zsh-users-unsubscribe@zsh.org>

<zsh-workers-unsubscribe@zsh.org>

YOU ONLY NEED TO JOIN ONE OF THE MAILING LISTS AS THEY ARE NESTED. All submissions to zsh-announce are automatically forwarded to zsh-users. All submissions to zsh-users are automatically forwarded to zsh-workers.

If you have problems subscribing/unsubscribing to any of the mailing lists, send mail to <listmaster@zsh.org>.

The mailing lists are archived; the archives can be accessed via the administrative addresses listed above. There is also a hypertext archive available at https://www.zsh.org/mla/.

THE ZSH FAQ

Zsh has a list of Frequently Asked Questions (FAQ), maintained by Peter Stephenson <pws@zsh.org>. It is regularly posted to the newsgroup comp.unix.shell and the zsh-announce mailing list. The latest version can be found at any of the Zsh FTP sites, or at https://www.zsh.org/FAQ/. The contact address for FAQ-related matters is <faqmaster@zsh.org>.

THE ZSH WEB PAGE

Zsh has a web page which is located at https://www.zsh.org/. The contact address for web-related matters is <webmaster@zsh.org>.

THE ZSH USERGUIDE

A userguide is currently in preparation. It is intended to complement the manual, with explanations and hints on issues where the manual can be cabbalistic, hierographic, or downright mystifying (for example, the word `hierographic' does not exist). It can be viewed in its current state at https://zsh.sourceforge.io/Guide/. At the time of writing, chapters dealing with startup files and their contents and the new completion system were essentially complete.

INVOCATION

The following flags are interpreted by the shell when invoked to determine where the shell will read commands from:

-c

Take the first argument as a command to execute, rather than reading commands from a script or standard input. If any further arguments are given, the first one is assigned to $0, rather than being used as a positional parameter.

-i

Force shell to be interactive. It is still possible to specify a script to execute.

-s

Force shell to read commands from the standard input. If the -s flag is not present and an argument is given, the first argument is taken to be the pathname of a script to execute.

If there are any remaining arguments after option processing, and neither of the options -c or -s was supplied, the first argument is taken as the file name of a script containing shell commands to be executed. If the option PATH_SCRIPT is set, and the file name does not contain a directory path (i.e. there is no `/' in the name), first the current directory and then the command path given by the variable PATH are searched for the script. If the option is not set or the file name contains a `/' it is used directly.

After the first one or two arguments have been appropriated as described above, the remaining arguments are assigned to the positional parameters.

For further options, which are common to invocation and the set builtin, see zshoptions(1).

The long option `--emulate' followed (in a separate word) by an emulation mode may be passed to the shell. The emulation modes are those described for the emulate builtin, see zshbuiltins(1). The `--emulate' option must precede any other options (which might otherwise be overridden), but following options are honoured, so may be used to modify the requested emulation mode. Note that certain extra steps are taken to ensure a smooth emulation when this option is used compared with the emulate command within the shell: for example, variables that conflict with POSIX usage such as path are not defined within the shell.

Options may be specified by name using the -o option. -o acts like a single-letter option, but takes a following string as the option name. For example,

zsh -x -o shwordsplit scr

runs the script scr, setting the XTRACE option by the corresponding letter `-x' and the SH_WORD_SPLIT option by name. Options may be turned off by name by using +o instead of -o. -o can be stacked up with preceding single-letter options, so for example `-xo shwordsplit' or `-xoshwordsplit' is equivalent to `-x -o shwordsplit'.

Options may also be specified by name in GNU long option style, `--option-name'. When this is done, `-' characters in the option name are permitted: they are translated into `_', and thus ignored. So, for example, `zsh --sh-word-split' invokes zsh with the SH_WORD_SPLIT option turned on. Like other option syntaxes, options can be turned off by replacing the initial `-' with a `+'; thus `+-sh-word-split' is equivalent to `--no-sh-word-split'. Unlike other option syntaxes, GNU-style long options cannot be stacked with any other options, so for example `-x-shwordsplit' is an error, rather than being treated like `-x --shwordsplit'.

The special GNU-style option `--version' is handled; it sends to standard output the shell's version information, then exits successfully. `--help' is also handled; it sends to standard output a list of options that can be used when invoking the shell, then exits successfully.

Option processing may be finished, allowing following arguments that start with `-' or `+' to be treated as normal arguments, in two ways. Firstly, a lone `-' (or `+') as an argument by itself ends option processing. Secondly, a special option `--' (or `+-'), which may be specified on its own (which is the standard POSIX usage) or may be stacked with preceding options (so `-x-' is equivalent to `-x --'). Options are not permitted to be stacked after `--' (so `-x-f' is an error), but note the GNU-style option form discussed above, where `--shwordsplit' is permitted and does not end option processing.

Except when the sh/ksh emulation single-letter options are in effect, the option `-b' (or `+b') ends option processing. `-b' is like `--', except that further single-letter options can be stacked after the `-b' and will take effect as normal.

COMPATIBILITY

Zsh tries to emulate sh or ksh when it is invoked as sh or ksh respectively; more precisely, it looks at the first letter of the name by which it was invoked, excluding any initial `r' (assumed to stand for `restricted'), and if that is `b', `s' or `k' it will emulate sh or ksh. Furthermore, if invoked as su (which happens on certain systems when the shell is executed by the su command), the shell will try to find an alternative name from the SHELL environment variable and perform emulation based on that.

In sh and ksh compatibility modes the following parameters are not special and not initialized by the shell: ARGC, argv, cdpath, fignore, fpath, HISTCHARS, mailpath, MANPATH, manpath, path, prompt, PROMPT, PROMPT2, PROMPT3, PROMPT4, psvar, status.

The usual zsh startup/shutdown scripts are not executed. Login shells source /etc/profile followed by $HOME/.profile. If the ENV environment variable is set on invocation, $ENV is sourced after the profile scripts. The value of ENV is subjected to parameter expansion, command substitution, and arithmetic expansion before being interpreted as a pathname. Note that the PRIVILEGED option also affects the execution of startup files.

The following options are set if the shell is invoked as sh or ksh: NO_BAD_PATTERN, NO_BANG_HIST, NO_BG_NICE, NO_EQUALS, NO_FUNCTION_ARGZERO, GLOB_SUBST, NO_GLOBAL_EXPORT, NO_HUP, INTERACTIVE_COMMENTS, KSH_ARRAYS, NO_MULTIOS, NO_NOMATCH, NO_NOTIFY, POSIX_BUILTINS, NO_PROMPT_PERCENT, RM_STAR_SILENT, SH_FILE_EXPANSION, SH_GLOB, SH_OPTION_LETTERS, SH_WORD_SPLIT. Additionally the BSD_ECHO and IGNORE_BRACES options are set if zsh is invoked as sh. Also, the KSH_OPTION_PRINT, LOCAL_OPTIONS, PROMPT_BANG, PROMPT_SUBST and SINGLE_LINE_ZLE options are set if zsh is invoked as ksh.

Please note that, whilst reasonable efforts are taken to address incompatibilities when they arise, zsh does not guarantee complete emulation of other shells, nor POSIX compliance. For more information on the differences between zsh and other shells, please refer to chapter 2 of the shell FAQ, https://www.zsh.org/FAQ/.

RESTRICTED SHELL

When the basename of the command used to invoke zsh starts with the letter `r' or the `-r' command line option is supplied at invocation, the shell becomes restricted. Emulation mode is determined after stripping the letter `r' from the invocation name. The following are disabled in restricted mode:

•

changing directories with the cd builtin

•

changing or unsetting the EGID, EUID, GID, HISTFILE, HISTSIZE, IFS, LD_AOUT_LIBRARY_PATH, LD_AOUT_PRELOAD, LD_LIBRARY_PATH, LD_PRELOAD, MODULE_PATH, module_path, PATH, path, SHELL, UID and USERNAME parameters

•

specifying command names containing /

•

specifying command pathnames using hash

•

redirecting output to files

•

using the exec builtin command to replace the shell with another command

•

using jobs -Z to overwrite the shell process' argument and environment space

•

using the ARGV0 parameter to override argv[0] for external commands

•

turning off restricted mode with set +r or unsetopt RESTRICTED

These restrictions are enforced after processing the startup files. The startup files should set up PATH to point to a directory of commands which can be safely invoked in the restricted environment. They may also add further restrictions by disabling selected builtins.

Restricted mode can also be activated any time by setting the RESTRICTED option. This immediately enables all the restrictions described above even if the shell still has not processed all startup files.

A shell Restricted Mode is an outdated way to restrict what users may do: modern systems have better, safer and more reliable ways to confine user actions, such as chroot jails, containers and zones.

A restricted shell is very difficult to implement safely. The feature may be removed in a future version of zsh.

It is important to realise that the restrictions only apply to the shell, not to the commands it runs (except for some shell builtins). While a restricted shell can only run the restricted list of commands accessible via the predefined `PATH' variable, it does not prevent those commands from running any other command.

As an example, if `env' is among the list of allowed commands, then it allows the user to run any command as `env' is not a shell builtin command and can run arbitrary executables.

So when implementing a restricted shell framework it is important to be fully aware of what actions each of the allowed commands or features (which may be regarded as modules) can perform.

Many commands can have their behaviour affected by environment variables. Except for the few listed above, zsh does not restrict the setting of environment variables.

If a `perl', `python', `bash', or other general purpose interpreted script it treated as a restricted command, the user can work around the restriction by setting specially crafted `PERL5LIB', `PYTHONPATH', `BASHENV' (etc.) environment variables. On GNU systems, any command can be made to run arbitrary code when performing character set conversion (including zsh itself) by setting a `GCONV_PATH' environment variable. Those are only a few examples.

Bear in mind that, contrary to some other shells, `readonly' is not a security feature in zsh as it can be undone and so cannot be used to mitigate the above.

A restricted shell only works if the allowed commands are few and carefully written so as not to grant more access to users than intended. It is also important to restrict what zsh module the user may load as some of them, such as `zsh/system', `zsh/mapfile' and `zsh/files', allow bypassing most of the restrictions.

STARTUP/SHUTDOWN FILES

Commands are first read from /etc/zsh/zshenv; this cannot be overridden. Subsequent behaviour is modified by the RCS and GLOBAL_RCS options; the former affects all startup files, while the second only affects global startup files (those shown here with an path starting with a /). If one of the options is unset at any point, any subsequent startup file(s) of the corresponding type will not be read. It is also possible for a file in $ZDOTDIR to re-enable GLOBAL_RCS. Both RCS and GLOBAL_RCS are set by default.

Commands are then read from $ZDOTDIR/.zshenv. If the shell is a login shell, commands are read from /etc/zsh/zprofile and then $ZDOTDIR/.zprofile. Then, if the shell is interactive, commands are read from /etc/zsh/zshrc and then $ZDOTDIR/.zshrc. Finally, if the shell is a login shell, /etc/zsh/zlogin and $ZDOTDIR/.zlogin are read.

When a login shell exits, the files $ZDOTDIR/.zlogout and then /etc/zsh/zlogout are read. This happens with either an explicit exit via the exit or logout commands, or an implicit exit by reading end-of-file from the terminal. However, if the shell terminates due to exec'ing another process, the logout files are not read. These are also affected by the RCS and GLOBAL_RCS options. Note also that the RCS option affects the saving of history files, i.e. if RCS is unset when the shell exits, no history file will be saved.

If ZDOTDIR is unset, HOME is used instead. Files listed above as being in /etc may be in another directory, depending on the installation.

As /etc/zsh/zshenv is run for all instances of zsh, it is important that it be kept as small as possible. In particular, it is a good idea to put code that does not need to be run for every single shell behind a test of the form `if [[ -o rcs ]]; then ...' so that it will not be executed when zsh is invoked with the `-f' option.

Any of these files may be pre-compiled with the zcompile builtin command (see zshbuiltins(1)). If a compiled file exists (named for the original file plus the .zwc extension) and it is newer than the original file, the compiled file will be used instead.

NAME

zshroadmap - informal introduction to the zsh manual The Zsh Manual, like the shell itself, is large and often complicated. This section of the manual provides some pointers to areas of the shell that are likely to be of particular interest to new users, and indicates where in the rest of the manual the documentation is to be found.

WHEN THE SHELL STARTS

When it starts, the shell reads commands from various files. These can be created or edited to customize the shell. See the section Startup/Shutdown Files in zsh(1).

If no personal initialization files exist for the current user, a function is run to help you change some of the most common settings. It won't appear if your administrator has disabled the zsh/newuser module. The function is designed to be self-explanatory. You can run it by hand with `autoload -Uz zsh-newuser-install; zsh-newuser-install -f'. See also the section `User Configuration Functions' in zshcontrib(1).

INTERACTIVE USE

Interaction with the shell uses the builtin Zsh Line Editor, ZLE. This is described in detail in zshzle(1).

The first decision a user must make is whether to use the Emacs or Vi editing mode as the keys for editing are substantially different. Emacs editing mode is probably more natural for beginners and can be selected explicitly with the command bindkey -e.

A history mechanism for retrieving previously typed lines (most simply with the Up or Down arrow keys) is available; note that, unlike other shells, zsh will not save these lines when the shell exits unless you set appropriate variables, and the number of history lines retained by default is quite small (30 lines). See the description of the shell variables (referred to in the documentation as parameters) HISTFILE, HISTSIZE and SAVEHIST in zshparam(1). Note that it's currently only possible to read and write files saving history when the shell is interactive, i.e. it does not work from scripts.

The shell now supports the UTF-8 character set (and also others if supported by the operating system). This is (mostly) handled transparently by the shell, but the degree of support in terminal emulators is variable. There is some discussion of this in the shell FAQ, https://www.zsh.org/FAQ/. Note in particular that for combining characters to be handled the option COMBINING_CHARS needs to be set. Because the shell is now more sensitive to the definition of the character set, note that if you are upgrading from an older version of the shell you should ensure that the appropriate variable, either LANG (to affect all aspects of the shell's operation) or LC_CTYPE (to affect only the handling of character sets) is set to an appropriate value. This is true even if you are using a single-byte character set including extensions of ASCII such as ISO-8859-1 or ISO-8859-15. See the description of LC_CTYPE in zshparam(1).

OPTIONS

The shell has a large number of options for changing its behaviour. These cover all aspects of the shell; browsing the full documentation is the only good way to become acquainted with the many possibilities. See zshoptions(1).

PATTERN MATCHING

The shell has a rich set of patterns which are available for file matching (described in the documentation as `filename generation' and also known for historical reasons as `globbing') and for use when programming. These are described in the section `Filename Generation' in zshexpn(1).

Of particular interest are the following patterns that are not commonly supported by other systems of pattern matching:

**

for matching over multiple directories

|

for matching either of two alternatives

~, ^

the ability to exclude patterns from matching when the EXTENDED_GLOB option is set

(...)

glob qualifiers, included in parentheses at the end of the pattern, which select files by type (such as directories) or attribute (such as size).

GENERAL COMMENTS ON SYNTAX

Although the syntax of zsh is in ways similar to the Korn shell, and therefore more remotely to the original UNIX shell, the Bourne shell, its default behaviour does not entirely correspond to those shells. General shell syntax is introduced in the section `Shell Grammar' in zshmisc(1).

One commonly encountered difference is that variables substituted onto the command line are not split into words. See the description of the shell option SH_WORD_SPLIT in the section `Parameter Expansion' in zshexpn(1). In zsh, you can either explicitly request the splitting (e.g. ${=foo}) or use an array when you want a variable to expand to more than one word. See the section `Array Parameters' in zshparam(1).

PROGRAMMING

The most convenient way of adding enhancements to the shell is typically by writing a shell function and arranging for it to be autoloaded. Functions are described in the section `Functions' in zshmisc(1). Users changing from the C shell and its relatives should notice that aliases are less used in zsh as they don't perform argument substitution, only simple text replacement.

A few general functions, other than those for the line editor described above, are provided with the shell and are described in zshcontrib(1). Features include:

promptinit

a prompt theme system for changing prompts easily, see the section `Prompt Themes'

zsh-mime-setup

a MIME-handling system which dispatches commands according to the suffix of a file as done by graphical file managers

zcalc

a calculator

zargs

a version of xargs that makes the find command redundant

zmv

a command for renaming files by means of shell patterns.

NAME

zshmisc - everything and then some

SIMPLE COMMANDS & PIPELINES

A simple command is a sequence of optional parameter assignments followed by blank-separated words, with optional redirections interspersed. For a description of assignment, see the beginning of zshparam(1).

The first word is the command to be executed, and the remaining words, if any, are arguments to the command. If a command name is given, the parameter assignments modify the environment of the command when it is executed. The value of a simple command is its exit status, or 128 plus the signal number if terminated by a signal. For example,

echo foo

is a simple command with arguments.

A pipeline is either a simple command, or a sequence of two or more simple commands where each command is separated from the next by `|' or `|&'. Where commands are separated by `|', the standard output of the first command is connected to the standard input of the next. `|&' is shorthand for `2>&1 |', which connects both the standard output and the standard error of the command to the standard input of the next. The value of a pipeline is the value of the last command, unless the pipeline is preceded by `!' in which case the value is the logical inverse of the value of the last command. For example,

echo foo | sed 's/foo/bar/'

is a pipeline, where the output (`foo' plus a newline) of the first command will be passed to the input of the second.

If a pipeline is preceded by `coproc', it is executed as a coprocess; a two-way pipe is established between it and the parent shell. The shell can read from or write to the coprocess by means of the `>&p' and `<&p' redirection operators or with `print -p' and `read -p'. A pipeline cannot be preceded by both `coproc' and `!'. If job control is active, the coprocess can be treated in other than input and output as an ordinary background job.

A sublist is either a single pipeline, or a sequence of two or more pipelines separated by `&&' or `||'. If two pipelines are separated by `&&', the second pipeline is executed only if the first succeeds (returns a zero status). If two pipelines are separated by `||', the second is executed only if the first fails (returns a nonzero status). Both operators have equal precedence and are left associative. The value of the sublist is the value of the last pipeline executed. For example,

dmesg | grep panic && print yes

is a sublist consisting of two pipelines, the second just a simple command which will be executed if and only if the grep command returns a zero status. If it does not, the value of the sublist is that return status, else it is the status returned by the print (almost certainly zero).

A list is a sequence of zero or more sublists, in which each sublist is terminated by `;', `&', `&|', `&!', or a newline. This terminator may optionally be omitted from the last sublist in the list when the list appears as a complex command inside `(...)' or `{...}'. When a sublist is terminated by `;' or newline, the shell waits for it to finish before executing the next sublist. If a sublist is terminated by a `&', `&|', or `&!', the shell executes the last pipeline in it in the background, and does not wait for it to finish (note the difference from other shells which execute the whole sublist in the background). A backgrounded pipeline returns a status of zero.

More generally, a list can be seen as a set of any shell commands whatsoever, including the complex commands below; this is implied wherever the word `list' appears in later descriptions. For example, the commands in a shell function form a special sort of list.

PRECOMMAND MODIFIERS

A simple command may be preceded by a precommand modifier, which will alter how the command is interpreted. These modifiers are shell builtin commands with the exception of nocorrect which is a reserved word.

-

The command is executed with a `-' prepended to its argv[0] string.

builtin

The command word is taken to be the name of a builtin command, rather than a shell function or external command.

command [ -pvV ]

The command word is taken to be the name of an external command, rather than a shell function or builtin. If the POSIX_BUILTINS option is set, builtins will also be executed but certain special properties of them are suppressed. The -p flag causes a default path to be searched instead of that in $path. With the -v flag, command is similar to whence and with -V, it is equivalent to whence -v.

exec [ -cl ] [ -a argv0 ]

The following command together with any arguments is run in place of the current process, rather than as a sub-process. The shell does not fork and is replaced. The shell does not invoke TRAPEXIT, nor does it source zlogout files. The options are provided for compatibility with other shells.

nocorrect

Spelling correction is not done on any of the words. This must appear before any other precommand modifier, as it is interpreted immediately, before any parsing is done. It has no effect in non-interactive shells.

noglob

Filename generation (globbing) is not performed on any of the words.

COMPLEX COMMANDS

A complex command in zsh is one of the following:

if list then list [ elif list then list ] ... [ else list ] fi

The if list is executed, and if it returns a zero exit status, the then list is executed. Otherwise, the elif list is executed and if its status is zero, the then list is executed. If each elif list returns nonzero status, the else list is executed.

for name ... [ in word ... ] term do list done

Expand the list of words, and set the parameter name to each of them in turn, executing list each time. If the `in word' is omitted, use the positional parameters instead of the words.

for (( [expr1] ; [expr2] ; [expr3] )) do list done

The arithmetic expression expr1 is evaluated first (see the section `Arithmetic Evaluation'). The arithmetic expression expr2 is repeatedly evaluated until it evaluates to zero and when non-zero, list is executed and the arithmetic expression expr3 evaluated. If any expression is omitted, then it behaves as if it evaluated to 1.

while list do list done

Execute the do list as long as the while list returns a zero exit status.

until list do list done

Execute the do list as long as until list returns a nonzero exit status.

repeat word do list done

word is expanded and treated as an arithmetic expression, which must evaluate to a number n. list is then executed n times.

case word in [ [(] pattern [ | pattern ] ... ) list (;;|;&|;|) ] ... esac

Execute the list associated with the first pattern that matches word, if any. The form of the patterns is the same as that used for filename generation. See the section `Filename Generation'.

select name [ in word ... term ] do list done

where term is one or more newline or ; to terminate the words. Print the set of words, each preceded by a number. If the in word is omitted, use the positional parameters. The PROMPT3 prompt is printed and a line is read from the line editor if the shell is interactive and that is active, or else standard input. If this line consists of the number of one of the listed words, then the parameter name is set to the word corresponding to this number. If this line is empty, the selection list is printed again. Otherwise, the value of the parameter name is set to null. The contents of the line read from standard input is saved in the parameter REPLY. list is executed for each selection until a break or end-of-file is encountered.

( list )

Execute list in a subshell. Traps set by the trap builtin are reset to their default values while executing list; an exception is that ignored signals will continue to be ignored if the option POSIXTRAPS is set.

{ list }

Execute list.

{ try-list } always { always-list }

First execute try-list. Regardless of errors, or break or continue commands encountered within try-list, execute always-list. Execution then continues from the result of the execution of try-list; in other words, any error, or break or continue command is treated in the normal way, as if always-list were not present. The two chunks of code are referred to as the `try block' and the `always block'.

{
    # code which may cause an error
  } always {
    # This code is executed regardless of the error.
    (( TRY_BLOCK_ERROR = 0 ))
}
# The error condition has been reset.

function [ -T ] word ... [ () ] [ term ] { list }

word ... () [ term ] { list }

word ... () [ term ] command

where term is one or more newline or ;. Define a function which is referenced by any one of word. Normally, only one word is provided; multiple words are usually only useful for setting traps. The body of the function is the list between the { and }. See the section `Functions'.

func() { ... } 2>&1

time [ pipeline ]

The pipeline is executed, and timing statistics are reported on the standard error in the form specified by the TIMEFMT parameter. If pipeline is omitted, print statistics about the shell process and its children.

[[ exp ]]

Evaluates the conditional expression exp and return a zero exit status if it is true. See the section `Conditional Expressions' for a description of exp.

ALTERNATE FORMS FOR COMPLEX COMMANDS

Many of zsh's complex commands have alternate forms. These are non-standard and are likely not to be obvious even to seasoned shell programmers; they should not be used anywhere that portability of shell code is a concern.

The short versions below only work if sublist is of the form `{ list }' or if the SHORT_LOOPS option is set. For the if, while and until commands, in both these cases the test part of the loop must also be suitably delimited, such as by `[[ ... ]]' or `(( ... ))', else the end of the test will not be recognized. For the for, repeat, case and select commands no such special form for the arguments is necessary, but the other condition (the special form of sublist or use of the SHORT_LOOPS option) still applies. The SHORT_REPEAT option is available to enable the short version only for the repeat command.

if list { list } [ elif list { list } ] ... [ else { list } ]

An alternate form of if. The rules mean that

if [[ -o ignorebraces ]] {
  print yes
}

if true {  # Does not work!
  print yes
}

if list sublist

A short form of the alternate if. The same limitations on the form of list apply as for the previous form.

for name ... ( word ... ) sublist

A short form of for.

for name ... [ in word ... ] term sublist

where term is at least one newline or ;. Another short form of for.

for (( [expr1] ; [expr2] ; [expr3] )) sublist

A short form of the arithmetic for command.

foreach name ... ( word ... ) list end

Another form of for.

while list { list }

An alternative form of while. Note the limitations on the form of list mentioned above.

until list { list }

An alternative form of until. Note the limitations on the form of list mentioned above.

repeat word sublist

This is a short form of repeat.

case word { [ [(] pattern [ | pattern ] ... ) list (;;|;&|;|) ] ... }

An alternative form of case.

select name [ in word ... term ] sublist

where term is at least one newline or ;. A short form of select.

function word ... [ () ] [ term ] sublist

This is a short form of function.

RESERVED WORDS

The following words are recognized as reserved words when used as the first word of a command unless quoted or disabled using disable -r:

do done esac then elif else fi for case if while function repeat time until select coproc nocorrect foreach end ! [[ { } declare export float integer local readonly typeset

Additionally, `}' is recognized in any position if neither the IGNORE_BRACES option nor the IGNORE_CLOSE_BRACES option is set.

ERRORS

Certain errors are treated as fatal by the shell: in an interactive shell, they cause control to return to the command line, and in a non-interactive shell they cause the shell to be aborted. In older versions of zsh, a non-interactive shell running a script would not abort completely, but would resume execution at the next command to be read from the script, skipping the remainder of any functions or shell constructs such as loops or conditions; this somewhat illogical behaviour can be recovered by setting the option CONTINUE_ON_ERROR.

Fatal errors found in non-interactive shells include:

•

Failure to parse shell options passed when invoking the shell

•

Failure to change options with the set builtin

•

Parse errors of all sorts, including failures to parse mathematical expressions

•

Failures to set or modify variable behaviour with typeset, local, declare, export, integer, float

•

Execution of incorrectly positioned loop control structures (continue, break)

•

Attempts to use regular expression with no regular expression module available

•

Disallowed operations when the RESTRICTED options is set

•

Failure to create a pipe needed for a pipeline

•

Failure to create a multio

•

Failure to autoload a module needed for a declared shell feature

•

Errors creating command or process substitutions

•

Syntax errors in glob qualifiers

•

File generation errors where not caught by the option BAD_PATTERN

•

All bad patterns used for matching within case statements

•

File generation failures where not caused by NO_MATCH or similar options

•

All file generation errors where the pattern was used to create a multio

•

Memory errors where detected by the shell

•

Invalid subscripts to shell variables

•

Attempts to assign read-only variables

•

Logical errors with variables such as assignment to the wrong type

•

Use of invalid variable names

•

Errors in variable substitution syntax

•

Failure to convert characters in $'...' expressions

If the POSIX_BUILTINS option is set, more errors associated with shell builtin commands are treated as fatal, as specified by the POSIX standard.

COMMENTS

In non-interactive shells, or in interactive shells with the INTERACTIVE_COMMENTS option set, a word beginning with the third character of the histchars parameter (`#' by default) causes that word and all the following characters up to a newline to be ignored.

ALIASING

Every eligible word in the shell input is checked to see if there is an alias defined for it. If so, it is replaced by the text of the alias if it is in command position (if it could be the first word of a simple command), or if the alias is global. If the replacement text ends with a space, the next word in the shell input is always eligible for purposes of alias expansion.

It is an error for the function name, word, in the sh-compatible function definition syntax `word () ...' to be a word that resulted from alias expansion, unless the ALIAS_FUNC_DEF option is set.

An alias is defined using the alias builtin; global aliases may be defined using the -g option to that builtin.

A word is defined as:

•

Any plain string or glob pattern

•

Any quoted string, using any quoting method (note that the quotes must be part of the alias definition for this to be eligible)

•

Any parameter reference or command substitution

•

Any series of the foregoing, concatenated without whitespace or other tokens between them

•

Any reserved word (case, do, else, etc.)

•

With global aliasing, any command separator, any redirection operator, and `(' or `)' when not part of a glob pattern

Alias expansion is done on the shell input before any other expansion except history expansion. Therefore, if an alias is defined for the word foo, alias expansion may be avoided by quoting part of the word, e.g. \foo. Any form of quoting works, although there is nothing to prevent an alias being defined for the quoted form such as \foo as well.

In particular, note that quoting must be used when using unalias to remove global aliases:

% alias -g foo=bar
% unalias foo
unalias: no such hash table element: bar
% unalias \foo
% 

When POSIX_ALIASES is set, only plain unquoted strings are eligible for aliasing. The alias builtin does not reject ineligible aliases, but they are not expanded.

For use with completion, which would remove an initial backslash followed by a character that isn't special, it may be more convenient to quote the word by starting with a single quote, i.e. 'foo; completion will automatically add the trailing single quote.

alias echobar='echo bar'; echobar

QUOTING

A character may be quoted (that is, made to stand for itself) by preceding it with a `\'. `\' followed by a newline is ignored.

A string enclosed between `$'' and `'' is processed the same way as the string arguments of the print builtin, and the resulting string is considered to be entirely quoted. A literal `'' character can be included in the string by using the `\'' escape.

All characters enclosed between a pair of single quotes ('') that is not preceded by a `$' are quoted. A single quote cannot appear within single quotes unless the option RC_QUOTES is set, in which case a pair of single quotes are turned into a single quote. For example,

print ''''

outputs nothing apart from a newline if RC_QUOTES is not set, but one single quote if it is set.

Inside double quotes (""), parameter and command substitution occur, and `\' quotes the characters `\', ``', `"', `$', and the first character of $histchars (default `!').

REDIRECTION

If a command is followed by & and job control is not active, then the default standard input for the command is the empty file /dev/null. Otherwise, the environment for the execution of a command contains the file descriptors of the invoking shell as modified by input/output specifications.

The following may appear anywhere in a simple command or may precede or follow a complex command. Expansion occurs before word or digit is used except as noted below. If the result of substitution on word produces more than one filename, redirection occurs for each separate filename in turn.

< word

Open file word for reading as standard input. It is an error to open a file in this fashion if it does not exist.

<> word

Open file word for reading and writing as standard input. If the file does not exist then it is created.

> word

Open file word for writing as standard output. If the file does not exist then it is created. If the file exists, and the CLOBBER option is unset, this causes an error; otherwise, it is truncated to zero length.

>| word

>! word

Same as >, except that the file is truncated to zero length if it exists, regardless of CLOBBER.

>> word

Open file word for writing in append mode as standard output. If the file does not exist, and the CLOBBER and APPEND_CREATE options are both unset, this causes an error; otherwise, the file is created.

>>| word

>>! word

Same as >>, except that the file is created if it does not exist, regardless of CLOBBER and APPEND_CREATE.

<<[-] word

The shell input is read up to a line that is the same as word, or to an end-of-file. No parameter expansion, command substitution or filename generation is performed on word. The resulting document, called a here-document, becomes the standard input.

<<< word

Perform shell expansion on word and pass the result to standard input. This is known as a here-string. Compare the use of word in here-documents above, where word does not undergo shell expansion. The result will have a trailing newline after it.

<& number

>& number

The standard input/output is duplicated from file descriptor number (see dup2(2)).

<& -

>& -

Close the standard input/output.

<& p

>& p

The input/output from/to the coprocess is moved to the standard input/output.

>& word

&> word

(Except where `>& word' matches one of the above syntaxes; `&>' can always be used to avoid this ambiguity.) Redirects both standard output and standard error (file descriptor 2) in the manner of `> word'. Note that this does not have the same effect as `> word 2>&1' in the presence of multios (see the section below).

>&| word

>&! word

&>| word

&>! word

Redirects both standard output and standard error (file descriptor 2) in the manner of `>| word'.

>>& word

&>> word

Redirects both standard output and standard error (file descriptor 2) in the manner of `>> word'.

>>&| word

>>&! word

&>>| word

&>>! word

Redirects both standard output and standard error (file descriptor 2) in the manner of `>>| word'.

If one of the above is preceded by a digit, then the file descriptor referred to is that specified by the digit instead of the default 0 or 1. The order in which redirections are specified is significant. The shell evaluates each redirection in terms of the (file descriptor, file) association at the time of evaluation. For example:

... 1>fname 2>&1

first associates file descriptor 1 with file fname. It then associates file descriptor 2 with the file associated with file descriptor 1 (that is, fname). If the order of redirections were reversed, file descriptor 2 would be associated with the terminal (assuming file descriptor 1 had been) and then file descriptor 1 would be associated with file fname.

The `|&' command separator described in Simple Commands & Pipelines in zshmisc(1) is a shorthand for `2>&1 |'.

The various forms of process substitution, `<(list)', and `=(list)' for input and `>(list)' for output, are often used together with redirection. For example, if word in an output redirection is of the form `>(list)' then the output is piped to the command represented by list. See Process Substitution in zshexpn(1).

OPENING FILE DESCRIPTORS USING PARAMETERS

When the shell is parsing arguments to a command, and the shell option IGNORE_BRACES is not set, a different form of redirection is allowed: instead of a digit before the operator there is a valid shell identifier enclosed in braces. The shell will open a new file descriptor that is guaranteed to be at least 10 and set the parameter named by the identifier to the file descriptor opened. No whitespace is allowed between the closing brace and the redirection character. For example:

... {myfd}>&1

This opens a new file descriptor that is a duplicate of file descriptor 1 and sets the parameter myfd to the number of the file descriptor, which will be at least 10. The new file descriptor can be written to using the syntax >&$myfd. The file descriptor remains open in subshells and forked external executables.

The syntax {varid}>&-, for example {myfd}>&-, may be used to close a file descriptor opened in this fashion. Note that the parameter given by varid must previously be set to a file descriptor in this case.

It is an error to open or close a file descriptor in this fashion when the parameter is readonly. However, it is not an error to read or write a file descriptor using <&$param or >&$param if param is readonly.

If the option CLOBBER is unset, it is an error to open a file descriptor using a parameter that is already set to an open file descriptor previously allocated by this mechanism. Unsetting the parameter before using it for allocating a file descriptor avoids the error.

Note that this mechanism merely allocates or closes a file descriptor; it does not perform any redirections from or to it. It is usually convenient to allocate a file descriptor prior to use as an argument to exec. The syntax does not in any case work when used around complex commands such as parenthesised subshells or loops, where the opening brace is interpreted as part of a command list to be executed in the current shell.

The following shows a typical sequence of allocation, use, and closing of a file descriptor:

integer myfd
exec {myfd}>~/logs/mylogfile.txt
print This is a log message. >&$myfd
exec {myfd}>&-

Note that the expansion of the variable in the expression >&$myfd occurs at the point the redirection is opened. This is after the expansion of command arguments and after any redirections to the left on the command line have been processed.

MULTIOS

If the user tries to open a file descriptor for writing more than once, the shell opens the file descriptor as a pipe to a process that copies its input to all the specified outputs, similar to tee, provided the MULTIOS option is set, as it is by default. Thus:

date >foo >bar

writes the date to two files, named `foo' and `bar'. Note that a pipe is an implicit redirection; thus

date >foo | cat

writes the date to the file `foo', and also pipes it to cat.

Note that the shell opens all the files to be used in the multio process immediately, not at the point they are about to be written.

Note also that redirections are always expanded in order. This happens regardless of the setting of the MULTIOS option, but with the option in effect there are additional consequences. For example, the meaning of the expression >&1 will change after a previous redirection:

date >&1 >output

In the case above, the >&1 refers to the standard output at the start of the line; the result is similar to the tee command. However, consider:

date >output >&1

As redirections are evaluated in order, when the >&1 is encountered the standard output is set to the file output and another copy of the output is therefore sent to that file. This is unlikely to be what is intended.

If the MULTIOS option is set, the word after a redirection operator is also subjected to filename generation (globbing). Thus

: > *

will truncate all files in the current directory, assuming there's at least one. (Without the MULTIOS option, it would create an empty file called `*'.) Similarly, you can do

echo exit 0 >> *.sh

If the user tries to open a file descriptor for reading more than once, the shell opens the file descriptor as a pipe to a process that copies all the specified inputs to its output in the order specified, provided the MULTIOS option is set. It should be noted that each file is opened immediately, not at the point where it is about to be read: this behaviour differs from cat, so if strictly standard behaviour is needed, cat should be used instead.

Thus

sort <foo <fubar

or even

sort <f{oo,ubar}

is equivalent to `cat foo fubar | sort'.

Expansion of the redirection argument occurs at the point the redirection is opened, at the point described above for the expansion of the variable in >&$myfd.

Note that a pipe is an implicit redirection; thus

cat bar | sort <foo

is equivalent to `cat bar foo | sort' (note the order of the inputs).

If the MULTIOS option is unset, each redirection replaces the previous redirection for that file descriptor. However, all files redirected to are actually opened, so

echo Hello > bar > baz

when MULTIOS is unset will truncate `bar', and write `Hello' into `baz'.

There is a problem when an output multio is attached to an external program. A simple example shows this:

cat file >file1 >file2
cat file1 file2

Here, it is possible that the second `cat' will not display the full contents of file1 and file2 (i.e. the original contents of file repeated twice).

The reason for this is that the multios are spawned after the cat process is forked from the parent shell, so the parent shell does not wait for the multios to finish writing data. This means the command as shown can exit before file1 and file2 are completely written. As a workaround, it is possible to run the cat process as part of a job in the current shell:

{ cat file } >file >file2

Here, the {...} job will pause to wait for both files to be written.

REDIRECTIONS WITH NO COMMAND

When a simple command consists of one or more redirection operators and zero or more parameter assignments, but no command name, zsh can behave in several ways.

If the parameter NULLCMD is not set or the option CSH_NULLCMD is set, an error is caused. This is the csh behavior and CSH_NULLCMD is set by default when emulating csh.

If the option SH_NULLCMD is set, the builtin `:' is inserted as a command with the given redirections. This is the default when emulating sh or ksh.

Otherwise, if the parameter NULLCMD is set, its value will be used as a command with the given redirections. If both NULLCMD and READNULLCMD are set, then the value of the latter will be used instead of that of the former when the redirection is an input. The default for NULLCMD is `cat' and for READNULLCMD is `more'. Thus

< file

shows the contents of file on standard output, with paging if that is a terminal. NULLCMD and READNULLCMD may refer to shell functions.

COMMAND EXECUTION

If a command name contains no slashes, the shell attempts to locate it. If there exists a shell function by that name, the function is invoked as described in the section `Functions'. If there exists a shell builtin by that name, the builtin is invoked.

Otherwise, the shell searches each element of $path for a directory containing an executable file by that name.

If execution fails: an error message is printed, and one of the following values is returned.

127

The search was unsuccessful. The error message is `command not found: cmd'.

126

The executable file has insufficient permissions, is a directory or special file, or is not a script and is in a format unrecognized by the operating system. The exact conditions and error message are operating system-dependent; see execve(2).

If execution fails because the file is not in executable format, and the file is not a directory, it is assumed to be a shell script. /bin/sh is spawned to execute it. If the program is a file beginning with `#!', the remainder of the first line specifies an interpreter for the program. The shell will execute the specified interpreter on operating systems that do not handle this executable format in the kernel.

If no external command is found but a function command_not_found_handler exists the shell executes this function with all command line arguments. The return status of the function becomes the status of the command. Note that the handler is executed in a subshell forked to execute an external command, hence changes to directories, shell parameters, etc. have no effect on the main shell.

FUNCTIONS

Shell functions are defined with the function reserved word or the special syntax `funcname ()'. Shell functions are read in and stored internally. Alias names are resolved when the function is read. Functions are executed like commands with the arguments passed as positional parameters. (See the section `Command Execution'.)

Functions execute in the same process as the caller and share all files and present working directory with the caller. A trap on EXIT set inside a function is executed after the function completes in the environment of the caller.

The return builtin is used to return from function calls.

Function identifiers can be listed with the functions builtin. Functions can be undefined with the unfunction builtin.

AUTOLOADING FUNCTIONS

A function can be marked as undefined using the autoload builtin (or `functions -u' or `typeset -fu'). Such a function has no body. When the function is first executed, the shell searches for its definition using the elements of the fpath variable. Thus to define functions for autoloading, a typical sequence is:

fpath=(~/myfuncs $fpath)
autoload myfunc1 myfunc2 ...

The usual alias expansion during reading will be suppressed if the autoload builtin or its equivalent is given the option -U. This is recommended for the use of functions supplied with the zsh distribution. Note that for functions precompiled with the zcompile builtin command the flag -U must be provided when the .zwc file is created, as the corresponding information is compiled into the latter.

For each element in fpath, the shell looks for three possible files, the newest of which is used to load the definition for the function:

element.zwc

A file created with the zcompile builtin command, which is expected to contain the definitions for all functions in the directory named element. The file is treated in the same manner as a directory containing files for functions and is searched for the definition of the function. If the definition is not found, the search for a definition proceeds with the other two possibilities described below.

element/function.zwc

A file created with zcompile, which is expected to contain the definition for function. It may include other function definitions as well, but those are neither loaded nor executed; a file found in this way is searched only for the definition of function.

element/function

A file of zsh command text, taken to be the definition for function.

In summary, the order of searching is, first, in the parents of directories in fpath for the newer of either a compiled directory or a directory in fpath; second, if more than one of these contains a definition for the function that is sought, the leftmost in the fpath is chosen; and third, within a directory, the newer of either a compiled function or an ordinary function definition is used.

If the KSH_AUTOLOAD option is set, or the file contains only a simple definition of the function, the file's contents will be executed. This will normally define the function in question, but may also perform initialization, which is executed in the context of the function execution, and may therefore define local parameters. It is an error if the function is not defined by loading the file.

Otherwise, the function body (with no surrounding `funcname() {...}') is taken to be the complete contents of the file. This form allows the file to be used directly as an executable shell script. If processing of the file results in the function being re-defined, the function itself is not re-executed. To force the shell to perform initialization and then call the function defined, the file should contain initialization code (which will be executed then discarded) in addition to a complete function definition (which will be retained for subsequent calls to the function), and a call to the shell function, including any arguments, at the end.

For example, suppose the autoload file func contains

func() { print This is func; }
print func is initialized

then `func; func' with KSH_AUTOLOAD set will produce both messages on the first call, but only the message `This is func' on the second and subsequent calls. Without KSH_AUTOLOAD set, it will produce the initialization message on the first call, and the other message on the second and subsequent calls.

It is also possible to create a function that is not marked as autoloaded, but which loads its own definition by searching fpath, by using `autoload -X' within a shell function. For example, the following are equivalent:

myfunc() {
  autoload -X
}
myfunc args...

and

unfunction myfunc   # if myfunc was defined
autoload myfunc
myfunc args...

In fact, the functions command outputs `builtin autoload -X' as the body of an autoloaded function. This is done so that

eval "$(functions)"

produces a reasonable result. A true autoloaded function can be identified by the presence of the comment `# undefined' in the body, because all comments are discarded from defined functions.

To load the definition of an autoloaded function myfunc without executing myfunc, use:

autoload +X myfunc

ANONYMOUS FUNCTIONS

If no name is given for a function, it is `anonymous' and is handled specially. Either form of function definition may be used: a `()' with no preceding name, or a `function' with an immediately following open brace. The function is executed immediately at the point of definition and is not stored for future use. The function name is set to `(anon)'.

Arguments to the function may be specified as words following the closing brace defining the function, hence if there are none no arguments (other than $0) are set. This is a difference from the way other functions are parsed: normal function definitions may be followed by certain keywords such as `else' or `fi', which will be treated as arguments to anonymous functions, so that a newline or semicolon is needed to force keyword interpretation.

Note also that the argument list of any enclosing script or function is hidden (as would be the case for any other function called at this point).

Redirections may be applied to the anonymous function in the same manner as to a current-shell structure enclosed in braces. The main use of anonymous functions is to provide a scope for local variables. This is particularly convenient in start-up files as these do not provide their own local variable scope.

For example,

variable=outside
function {
  local variable=inside
  print "I am $variable with arguments $*"
} this and that
print "I am $variable"

outputs the following:

I am inside with arguments this and that
I am outside

Note that function definitions with arguments that expand to nothing, for example `name=; function $name { ... }', are not treated as anonymous functions. Instead, they are treated as normal function definitions where the definition is silently discarded.

SPECIAL FUNCTIONS

Certain functions, if defined, have special meaning to the shell.

zshaddhistory() {
  print -sr -- ${1%%$'\n'}
  fc -p .zsh_local_history
}

TRAPINT() {
  print "Caught SIGINT, aborting."
  return $(( 128 + $1 ))
}

TRAPNAL() { 
 # code
}

trap '
 # code
' NAL

JOBS

If the MONITOR option is set, an interactive shell associates a job with each pipeline. It keeps a table of current jobs, printed by the jobs command, and assigns them small integer numbers. When a job is started asynchronously with `&', the shell prints a line to standard error which looks like:

[1] 1234

indicating that the job which was started asynchronously was job number 1 and had one (top-level) process, whose process ID was 1234.

If a job is started with `&|' or `&!', then that job is immediately disowned. After startup, it does not have a place in the job table, and is not subject to the job control features described here.

If you are running a job and wish to do something else you may hit the key ^Z (control-Z) which sends a TSTP signal to the current job: this key may be redefined by the susp option of the external stty command. The shell will then normally indicate that the job has been `suspended', and print another prompt. You can then manipulate the state of this job, putting it in the background with the bg command, or run some other commands and then eventually bring the job back into the foreground with the foreground command fg. A ^Z takes effect immediately and is like an interrupt in that pending output and unread input are discarded when it is typed.

A job being run in the background will suspend if it tries to read from the terminal.

Note that if the job running in the foreground is a shell function, then suspending it will have the effect of causing the shell to fork. This is necessary to separate the function's state from that of the parent shell performing the job control, so that the latter can return to the command line prompt. As a result, even if fg is used to continue the job the function will no longer be part of the parent shell, and any variables set by the function will not be visible in the parent shell. Thus the behaviour is different from the case where the function was never suspended. Zsh is different from many other shells in this regard.

One additional side effect is that use of disown with a job created by suspending shell code in this fashion is delayed: the job can only be disowned once any process started from the parent shell has terminated. At that point, the disowned job disappears silently from the job list.

The same behaviour is found when the shell is executing code as the right hand side of a pipeline or any complex shell construct such as if, for, etc., in order that the entire block of code can be managed as a single job. Background jobs are normally allowed to produce output, but this can be disabled by giving the command `stty tostop'. If you set this tty option, then background jobs will suspend when they try to produce output like they do when they try to read input.

When a command is suspended and continued later with the fg or wait builtins, zsh restores tty modes that were in effect when it was suspended. This (intentionally) does not apply if the command is continued via `kill -CONT', nor when it is continued with bg.

There are several ways to refer to jobs in the shell. A job can be referred to by the process ID of any process of the job or by one of the following:

%number

The job with the given number.

%string

The last job whose command line begins with string.

%?string

The last job whose command line contains string.

%%

Current job.

%+

Equivalent to `%%'.

%-

Previous job.

The shell learns immediately whenever a process changes state. It normally informs you whenever a job becomes blocked so that no further progress is possible. If the NOTIFY option is not set, it waits until just before it prints a prompt before it informs you. All such notifications are sent directly to the terminal, not to the standard output or standard error.

When the monitor mode is on, each background job that completes triggers any trap set for CHLD.

When you try to leave the shell while jobs are running or suspended, you will be warned that `You have suspended (running) jobs'. You may use the jobs command to see what they are. If you do this or immediately try to exit again, the shell will not warn you a second time; the suspended jobs will be terminated, and the running jobs will be sent a SIGHUP signal, if the HUP option is set.

To avoid having the shell terminate the running jobs, either use the nohup(1) command or the disown builtin.

SIGNALS

The INT and QUIT signals for an invoked command are ignored if the command is followed by `&' and the MONITOR option is not active. The shell itself always ignores the QUIT signal. Otherwise, signals have the values inherited by the shell from its parent (but see the TRAPNAL special functions in the section `Functions').

Certain jobs are run asynchronously by the shell other than those explicitly put into the background; even in cases where the shell would usually wait for such jobs, an explicit exit command or exit due to the option ERR_EXIT will cause the shell to exit without waiting. Examples of such asynchronous jobs are process substitution, see the section PROCESS SUBSTITUTION in the zshexpn(1) manual page, and the handler processes for multios, see the section MULTIOS in the zshmisc(1) manual page.

ARITHMETIC EVALUATION

The shell can perform integer and floating point arithmetic, either using the builtin let, or via a substitution of the form $((...)). For integers, the shell is usually compiled to use 8-byte precision where this is available, otherwise precision is 4 bytes. This can be tested, for example, by giving the command `print - $(( 12345678901 ))'; if the number appears unchanged, the precision is at least 8 bytes. Floating point arithmetic always uses the `double' type with whatever corresponding precision is provided by the compiler and the library.

The let builtin command takes arithmetic expressions as arguments; each is evaluated separately. Since many of the arithmetic operators, as well as spaces, require quoting, an alternative form is provided: for any command which begins with a `((', all the characters until a matching `))' are treated as a double-quoted expression and arithmetic expansion performed as for an argument of let. More precisely, `((...))' is equivalent to `let "..."'. The return status is 0 if the arithmetic value of the expression is non-zero, 1 if it is zero, and 2 if an error occurred.

For example, the following statement

(( val = 2 + 1 ))

is equivalent to

let "val = 2 + 1"

both assigning the value 3 to the shell variable val and returning a zero status.

Integers can be in bases other than 10. A leading `0x' or `0X' denotes hexadecimal and a leading `0b' or `0B' binary. Integers may also be of the form `base#n', where base is a decimal number between two and thirty-six representing the arithmetic base and n is a number in that base (for example, `16#ff' is 255 in hexadecimal). The base# may also be omitted, in which case base 10 is used. For backwards compatibility the form `[base]n' is also accepted.

An integer expression or a base given in the form `base#n' may contain underscores (`_') after the leading digit for visual guidance; these are ignored in computation. Examples are 1_000_000 or 0xffff_ffff which are equivalent to 1000000 and 0xffffffff respectively.

It is also possible to specify a base to be used for output in the form `[#base]', for example `[#16]'. This is used when outputting arithmetical substitutions or when assigning to scalar parameters, but an explicitly defined integer or floating point parameter will not be affected. If an integer variable is implicitly defined by an arithmetic expression, any base specified in this way will be set as the variable's output arithmetic base as if the option `-i base' to the typeset builtin had been used. The expression has no precedence and if it occurs more than once in a mathematical expression, the last encountered is used. For clarity it is recommended that it appear at the beginning of an expression. As an example:

typeset -i 16 y
print $(( [#8] x = 32, y = 32 ))
print $x $y

outputs first `8#40', the rightmost value in the given output base, and then `8#40 16#20', because y has been explicitly declared to have output base 16, while x (assuming it does not already exist) is implicitly typed by the arithmetic evaluation, where it acquires the output base 8.

The base may be replaced or followed by an underscore, which may itself be followed by a positive integer (if it is missing the value 3 is used). This indicates that underscores should be inserted into the output string, grouping the number for visual clarity. The following integer specifies the number of digits to group together. For example:

setopt cbases
print $(( [#16_4] 65536 ** 2 ))

outputs `0x1_0000_0000'.

The feature can be used with floating point numbers, in which case the base must be omitted; grouping is away from the decimal point. For example,

zmodload zsh/mathfunc
print $(( [#_] sqrt(1e7) ))

outputs `3_162.277_660_168_379_5' (the number of decimal places shown may vary).

If the C_BASES option is set, hexadecimal numbers are output in the standard C format, for example `0xFF' instead of the usual `16#FF'. If the option OCTAL_ZEROES is also set (it is not by default), octal numbers will be treated similarly and hence appear as `077' instead of `8#77'. This option has no effect on the output of bases other than hexadecimal and octal, and these formats are always understood on input.

When an output base is specified using the `[#base]' syntax, an appropriate base prefix will be output if necessary, so that the value output is valid syntax for input. If the # is doubled, for example `[##16]', then no base prefix is output.

Floating point constants are recognized by the presence of a decimal point or an exponent. The decimal point may be the first character of the constant, but the exponent character e or E may not, as it will be taken for a parameter name. All numeric parts (before and after the decimal point and in the exponent) may contain underscores after the leading digit for visual guidance; these are ignored in computation.

An arithmetic expression uses nearly the same syntax and associativity of expressions as in C.

In the native mode of operation, the following operators are supported (listed in decreasing order of precedence):

+ - ! ~ ++ --

unary plus/minus, logical NOT, complement, {pre,post}{in,de}crement

<< >>

bitwise shift left, right

&

bitwise AND

^

bitwise XOR

|

bitwise OR

**

exponentiation

* / %

multiplication, division, modulus (remainder)

+ -

addition, subtraction

< > <= >=

comparison

== !=

equality and inequality

&&

logical AND

|| ^^

logical OR, XOR

? :

ternary operator

= += -= *= /= %= &= ^= |= <<= >>= &&= ||= ^^= **=

assignment

,

comma operator

The operators `&&', `||', `&&=', and `||=' are short-circuiting, and only one of the latter two expressions in a ternary operator is evaluated. Note the precedence of the bitwise AND, OR, and XOR operators.

With the option C_PRECEDENCES the precedences (but no other properties) of the operators are altered to be the same as those in most other languages that support the relevant operators:

+ - ! ~ ++ --

unary plus/minus, logical NOT, complement, {pre,post}{in,de}crement

**

exponentiation

* / %

multiplication, division, modulus (remainder)

+ -

addition, subtraction

<< >>

bitwise shift left, right

< > <= >=

comparison

== !=

equality and inequality

&

bitwise AND

^

bitwise XOR

|

bitwise OR

&&

logical AND

^^

logical XOR

||

logical OR

? :

ternary operator

= += -= *= /= %= &= ^= |= <<= >>= &&= ||= ^^= **=

assignment

,

comma operator

Note the precedence of exponentiation in both cases is below that of unary operators, hence `-3**2' evaluates as `9', not `-9'. Use parentheses where necessary: `-(3**2)'. This is for compatibility with other shells.

Mathematical functions can be called with the syntax `func(args)', where the function decides if the args is used as a string or a comma-separated list of arithmetic expressions. The shell currently defines no mathematical functions by default, but the module zsh/mathfunc may be loaded with the zmodload builtin to provide standard floating point mathematical functions.

An expression of the form `##x' where x is any character sequence such as `a', `^A', or `\M-\C-x' gives the value of this character and an expression of the form `#name' gives the value of the first character of the contents of the parameter name. Character values are according to the character set used in the current locale; for multibyte character handling the option MULTIBYTE must be set. Note that this form is different from `$#name', a standard parameter substitution which gives the length of the parameter name. `#\' is accepted instead of `##', but its use is deprecated.

Named parameters and subscripted arrays can be referenced by name within an arithmetic expression without using the parameter expansion syntax. For example,

((val2 = val1 * 2))

assigns twice the value of $val1 to the parameter named val2.

An internal integer representation of a named parameter can be specified with the integer builtin. Arithmetic evaluation is performed on the value of each assignment to a named parameter declared integer in this manner. Assigning a floating point number to an integer results in rounding towards zero.

Likewise, floating point numbers can be declared with the float builtin; there are two types, differing only in their output format, as described for the typeset builtin. The output format can be bypassed by using arithmetic substitution instead of the parameter substitution, i.e. `${float}' uses the defined format, but `$((float))' uses a generic floating point format.

Promotion of integer to floating point values is performed where necessary. In addition, if any operator which requires an integer (`&', `|', `^', `<<', `>>' and their equivalents with assignment) is given a floating point argument, it will be silently rounded towards zero except for `~' which rounds down.

Users should beware that, in common with many other programming languages but not software designed for calculation, the evaluation of an expression in zsh is taken a term at a time and promotion of integers to floating point does not occur in terms only containing integers. A typical result of this is that a division such as 6/8 is truncated, in this being rounded towards 0. The FORCE_FLOAT shell option can be used in scripts or functions where floating point evaluation is required throughout.

Scalar variables can hold integer or floating point values at different times; there is no memory of the numeric type in this case.

If a variable is first assigned in a numeric context without previously being declared, it will be implicitly typed as integer or float and retain that type either until the type is explicitly changed or until the end of the scope. This can have unforeseen consequences. For example, in the loop

for (( f = 0; f < 1; f += 0.1 )); do
# use $f
done

if f has not already been declared, the first assignment will cause it to be created as an integer, and consequently the operation `f += 0.1' will always cause the result to be truncated to zero, so that the loop will fail. A simple fix would be to turn the initialization into `f = 0.0'. It is therefore best to declare numeric variables with explicit types.

CONDITIONAL EXPRESSIONS

A conditional expression is used with the [[ compound command to test attributes of files and to compare strings. Each expression can be constructed from one or more of the following unary or binary expressions:

-a file

true if file exists.

-b file

true if file exists and is a block special file.

-c file

true if file exists and is a character special file.

-d file

true if file exists and is a directory.

-e file

true if file exists.

-f file

true if file exists and is a regular file.

-g file

true if file exists and has its setgid bit set.

-h file

true if file exists and is a symbolic link.

-k file

true if file exists and has its sticky bit set.

-n string

true if length of string is non-zero.

-o option

true if option named option is on. option may be a single character, in which case it is a single letter option name. (See the section `Specifying Options'.)

-p file

true if file exists and is a FIFO special file (named pipe).

-r file

true if file exists and is readable by current process.

-s file

true if file exists and has size greater than zero.

-t fd

true if file descriptor number fd is open and associated with a terminal device. (note: fd is not optional)

-u file

true if file exists and has its setuid bit set.

-v varname

true if shell variable varname is set.

-w file

true if file exists and is writable by current process.

-x file

true if file exists and is executable by current process. If file exists and is a directory, then the current process has permission to search in the directory.

-z string

true if length of string is zero.

-L file

true if file exists and is a symbolic link.

-O file

true if file exists and is owned by the effective user ID of this process.

-G file

true if file exists and its group matches the effective group ID of this process.

-S file

true if file exists and is a socket.

-N file

true if file exists and its access time is not newer than its modification time.

file1 -nt file2

true if file1 exists and is newer than file2.

file1 -ot file2

true if file1 exists and is older than file2.

file1 -ef file2

true if file1 and file2 exist and refer to the same file.

string = pattern

string == pattern

true if string matches pattern. The two forms are exactly equivalent. The `=' form is the traditional shell syntax (and hence the only one generally used with the test and [ builtins); the `==' form provides compatibility with other sorts of computer language.

string != pattern

true if string does not match pattern.

string =~ regexp

true if string matches the regular expression regexp. If the option RE_MATCH_PCRE is set regexp is tested as a PCRE regular expression using the zsh/pcre module, else it is tested as a POSIX extended regular expression using the zsh/regex module. Upon successful match, some variables will be updated; no variables are changed if the matching fails.

string1 < string2

true if string1 comes before string2 based on ASCII value of their characters.

string1 > string2

true if string1 comes after string2 based on ASCII value of their characters.

exp1 -eq exp2

true if exp1 is numerically equal to exp2. Note that for purely numeric comparisons use of the ((...)) builtin described in the section `ARITHMETIC EVALUATION' is more convenient than conditional expressions.

exp1 -ne exp2

true if exp1 is numerically not equal to exp2.

exp1 -lt exp2

true if exp1 is numerically less than exp2.

exp1 -gt exp2

true if exp1 is numerically greater than exp2.

exp1 -le exp2

true if exp1 is numerically less than or equal to exp2.

exp1 -ge exp2

true if exp1 is numerically greater than or equal to exp2.

( exp )

true if exp is true.

! exp

true if exp is false.

exp1 && exp2

true if exp1 and exp2 are both true.

exp1 || exp2

true if either exp1 or exp2 is true.

For compatibility, if there is a single argument that is not syntactically significant, typically a variable, the condition is treated as a test for whether the expression expands as a string of non-zero length. In other words, [[ $var ]] is the same as [[ -n $var ]]. It is recommended that the second, explicit, form be used where possible.

Normal shell expansion is performed on the file, string and pattern arguments, but the result of each expansion is constrained to be a single word, similar to the effect of double quotes.

Filename generation is not performed on any form of argument to conditions. However, it can be forced in any case where normal shell expansion is valid and when the option EXTENDED_GLOB is in effect by using an explicit glob qualifier of the form (#q) at the end of the string. A normal glob qualifier expression may appear between the `q' and the closing parenthesis; if none appears the expression has no effect beyond causing filename generation. The results of filename generation are joined together to form a single word, as with the results of other forms of expansion.

This special use of filename generation is only available with the [[ syntax. If the condition occurs within the [ or test builtin commands then globbing occurs instead as part of normal command line expansion before the condition is evaluated. In this case it may generate multiple words which are likely to confuse the syntax of the test command.

For example,

[[ -n file*(#qN) ]]

produces status zero if and only if there is at least one file in the current directory beginning with the string `file'. The globbing qualifier N ensures that the expression is empty if there is no matching file.

Pattern metacharacters are active for the pattern arguments; the patterns are the same as those used for filename generation, see zshexpn(1), but there is no special behaviour of `/' nor initial dots, and no glob qualifiers are allowed.

In each of the above expressions, if file is of the form `/dev/fd/n', where n is an integer, then the test applied to the open file whose descriptor number is n, even if the underlying system does not support the /dev/fd directory.

In the forms which do numeric comparison, the expressions exp undergo arithmetic expansion as if they were enclosed in $((...)).

For example, the following:

[[ ( -f foo || -f bar ) && $report = y* ]] && print File exists.

tests if either file foo or file bar exists, and if so, if the value of the parameter report begins with `y'; if the complete condition is true, the message `File exists.' is printed.

EXPANSION OF PROMPT SEQUENCES

Prompt sequences undergo a special form of expansion. This type of expansion is also available using the -P option to the print builtin.

If the PROMPT_SUBST option is set, the prompt string is first subjected to parameter expansion, command substitution and arithmetic expansion. See zshexpn(1).

Certain escape sequences may be recognised in the prompt string.

If the PROMPT_BANG option is set, a `!' in the prompt is replaced by the current history event number. A literal `!' may then be represented as `!!'.

If the PROMPT_PERCENT option is set, certain escape sequences that start with `%' are expanded. Many escapes are followed by a single character, although some of these take an optional integer argument that should appear between the `%' and the next character of the sequence. More complicated escape sequences are available to provide conditional expansion.

SIMPLE PROMPT ESCAPES

CONDITIONAL SUBSTRINGS IN PROMPTS

%v

The value of the first element of the psvar array parameter. Following the `%' with an integer gives that element of the array. Negative integers count from the end of the array.

%(x.true-text.false-text)

Specifies a ternary expression. The character following the x is arbitrary; the same character is used to separate the text for the `true' result from that for the `false' result. This separator may not appear in the true-text, except as part of a %-escape sequence. A `)' may appear in the false-text as `%)'. true-text and false-text may both contain arbitrarily-nested escape sequences, including further ternary expressions.

%<string<

%>string>

%[xstring]

Specifies truncation behaviour for the remainder of the prompt string. The third, deprecated, form is equivalent to `%xstringx', i.e. x may be `<' or `>'. The string will be displayed in place of the truncated portion of any string; note this does not undergo prompt expansion.

NAME

zshexpn - zsh expansion and substitution

DESCRIPTION

The following types of expansions are performed in the indicated order in five steps:

History Expansion

This is performed only in interactive shells.

Alias Expansion

Aliases are expanded immediately before the command line is parsed as explained under Aliasing in zshmisc(1).

Process Substitution

Parameter Expansion

Command Substitution

Arithmetic Expansion

Brace Expansion

These five are performed in left-to-right fashion. On each argument, any of the five steps that are needed are performed one after the other. Hence, for example, all the parts of parameter expansion are completed before command substitution is started. After these expansions, all unquoted occurrences of the characters `\',`'' and `"' are removed.

Filename Expansion

If the SH_FILE_EXPANSION option is set, the order of expansion is modified for compatibility with sh and ksh. In that case filename expansion is performed immediately after alias expansion, preceding the set of five expansions mentioned above.

Filename Generation

This expansion, commonly referred to as globbing, is always done last.

The following sections explain the types of expansion in detail.

HISTORY EXPANSION

History expansion allows you to use words from previous command lines in the command line you are typing. This simplifies spelling corrections and the repetition of complicated commands or arguments.

Immediately before execution, each command is saved in the history list, the size of which is controlled by the HISTSIZE parameter. The one most recent command is always retained in any case. Each saved command in the history list is called a history event and is assigned a number, beginning with 1 (one) when the shell starts up. The history number that you may see in your prompt (see EXPANSION OF PROMPT SEQUENCES in zshmisc(1)) is the number that is to be assigned to the next command.

print -r -- *.c(#q:s/#%(#b)s(*).c/'S${match[1]}.C'/)

PROCESS SUBSTITUTION

Each part of a command argument that takes the form `<(list)', `>(list)' or `=(list)' is subject to process substitution. The expression may be preceded or followed by other strings except that, to prevent clashes with commonly occurring strings and patterns, the last form must occur at the start of a command argument, and the forms are only expanded when first parsing command or assignment arguments. Process substitutions may be used following redirection operators; in this case, the substitution must appear with no trailing string.

Note that `<<(list)' is not a special syntax; it is equivalent to `< <(list)', redirecting standard input from the result of process substitution. Hence all the following documentation applies. The second form (with the space) is recommended for clarity.

In the case of the < or > forms, the shell runs the commands in list as a subprocess of the job executing the shell command line. If the system supports the /dev/fd mechanism, the command argument is the name of the device file corresponding to a file descriptor; otherwise, if the system supports named pipes (FIFOs), the command argument will be a named pipe. If the form with > is selected then writing on this special file will provide input for list. If < is used, then the file passed as an argument will be connected to the output of the list process. For example,

paste <(cut -f1 file1) <(cut -f3 file2) |
tee >(process1) >(process2) >/dev/null

cuts fields 1 and 3 from the files file1 and file2 respectively, pastes the results together, and sends it to the processes process1 and process2.

If =(...) is used instead of <(...), then the file passed as an argument will be the name of a temporary file containing the output of the list process. This may be used instead of the < form for a program that expects to lseek (see lseek(2)) on the input file.

There is an optimisation for substitutions of the form =(<<<arg), where arg is a single-word argument to the here-string redirection <<<. This form produces a file name containing the value of arg after any substitutions have been performed. This is handled entirely within the current shell. This is effectively the reverse of the special form $(<arg) which treats arg as a file name and replaces it with the file's contents.

The = form is useful as both the /dev/fd and the named pipe implementation of <(...) have drawbacks. In the former case, some programmes may automatically close the file descriptor in question before examining the file on the command line, particularly if this is necessary for security reasons such as when the programme is running setuid. In the second case, if the programme does not actually open the file, the subshell attempting to read from or write to the pipe will (in a typical implementation, different operating systems may have different behaviour) block for ever and have to be killed explicitly. In both cases, the shell actually supplies the information using a pipe, so that programmes that expect to lseek (see lseek(2)) on the file will not work.

Also note that the previous example can be more compactly and efficiently written (provided the MULTIOS option is set) as:

paste <(cut -f1 file1) <(cut -f3 file2) > >(process1) > >(process2)

The shell uses pipes instead of FIFOs to implement the latter two process substitutions in the above example.

There is an additional problem with >(process); when this is attached to an external command, the parent shell does not wait for process to finish and hence an immediately following command cannot rely on the results being complete. The problem and solution are the same as described in the section MULTIOS in zshmisc(1). Hence in a simplified version of the example above:

paste <(cut -f1 file1) <(cut -f3 file2) > >(process)

(note that no MULTIOS are involved), process will be run asynchronously as far as the parent shell is concerned. The workaround is:

{ paste <(cut -f1 file1) <(cut -f3 file2) } > >(process)

The extra processes here are spawned from the parent shell which will wait for their completion.

Another problem arises any time a job with a substitution that requires a temporary file is disowned by the shell, including the case where `&!' or `&|' appears at the end of a command containing a substitution. In that case the temporary file will not be cleaned up as the shell no longer has any memory of the job. A workaround is to use a subshell, for example,

(mycmd =(myoutput)) &!

as the forked subshell will wait for the command to finish then remove the temporary file.

A general workaround to ensure a process substitution endures for an appropriate length of time is to pass it as a parameter to an anonymous shell function (a piece of shell code that is run immediately with function scope). For example, this code:

() {
   print File $1:
   cat $1
} =(print This be the verse)

outputs something resembling the following

File /tmp/zsh6nU0kS:
This be the verse

The temporary file created by the process substitution will be deleted when the function exits.

PARAMETER EXPANSION

The character `$' is used to introduce parameter expansions. See zshparam(1) for a description of parameters, including arrays, associative arrays, and subscript notation to access individual array elements.

Note in particular the fact that words of unquoted parameters are not automatically split on whitespace unless the option SH_WORD_SPLIT is set; see references to this option below for more details. This is an important difference from other shells. However, as in other shells, null words are elided from unquoted parameters' expansions.

With default options, after the assignments:

array=("first word" "" "third word")
scalar="only word"

then $array substitutes two words, `first word' and `third word', and $scalar substitutes a single word `only word'. Note that second element of array was elided. Scalar parameters can be elided too if their value is null (empty). To avoid elision, use quoting as follows: "$scalar" for scalars and "${array[@]}" or "${(@)array}" for arrays. (The last two forms are equivalent.)

Parameter expansions can involve flags, as in `${(@kv)aliases}', and other operators, such as `${PREFIX:-"/usr/local"}'. Parameter expansions can also be nested. These topics will be introduced below. The full rules are complicated and are noted at the end.

In the expansions discussed below that require a pattern, the form of the pattern is the same as that used for filename generation; see the section `Filename Generation'. Note that these patterns, along with the replacement text of any substitutions, are themselves subject to parameter expansion, command substitution, and arithmetic expansion. In addition to the following operations, the colon modifiers described in the section `Modifiers' in the section `History Expansion' can be applied: for example, ${i:s/foo/bar/} performs string substitution on the expansion of parameter $i.

In the following descriptions, `word' refers to a single word substituted on the command line, not necessarily a space delimited word.

${name}

The value, if any, of the parameter name is substituted. The braces are required if the expansion is to be followed by a letter, digit, or underscore that is not to be interpreted as part of name. In addition, more complicated forms of substitution usually require the braces to be present; exceptions, which only apply if the option KSH_ARRAYS is not set, are a single subscript or any colon modifiers appearing after the name, or any of the characters `^', `=', `~', `#' or `+' appearing before the name, all of which work with or without braces.

${+name}

If name is the name of a set parameter `1' is substituted, otherwise `0' is substituted.

${name-word}

${name:-word}

If name is set, or in the second form is non-null, then substitute its value; otherwise substitute word. In the second form name may be omitted, in which case word is always substituted.

${name+word}

${name:+word}

If name is set, or in the second form is non-null, then substitute word; otherwise substitute nothing.

${name=word}

${name:=word}

${name::=word}

In the first form, if name is unset then set it to word; in the second form, if name is unset or null then set it to word; and in the third form, unconditionally set name to word. In all forms, the value of the parameter is then substituted.

${name?word}

${name:?word}

In the first form, if name is set, or in the second form if name is both set and non-null, then substitute its value; otherwise, print word and exit from the shell. Interactive shells instead return to the prompt. If word is omitted, then a standard message is printed.

In any of the above expressions that test a variable and substitute an alternate word, note that you can use standard shell quoting in the word value to selectively override the splitting done by the SH_WORD_SPLIT option and the = flag, but not splitting by the s:string: flag.

In the following expressions, when name is an array and the substitution is not quoted, or if the `(@)' flag or the name[@] syntax is used, matching and replacement is performed on each array element separately.

${name#pattern}

${name##pattern}

If the pattern matches the beginning of the value of name, then substitute the value of name with the matched portion deleted; otherwise, just substitute the value of name. In the first form, the smallest matching pattern is preferred; in the second form, the largest matching pattern is preferred.

${name%pattern}

${name%%pattern}

If the pattern matches the end of the value of name, then substitute the value of name with the matched portion deleted; otherwise, just substitute the value of name. In the first form, the smallest matching pattern is preferred; in the second form, the largest matching pattern is preferred.

${name:#pattern}

If the pattern matches the value of name, then substitute the empty string; otherwise, just substitute the value of name. If name is an array the matching array elements are removed (use the `(M)' flag to remove the non-matched elements).

${name:|arrayname}

If arrayname is the name (N.B., not contents) of an array variable, then any elements contained in arrayname are removed from the substitution of name. If the substitution is scalar, either because name is a scalar variable or the expression is quoted, the elements of arrayname are instead tested against the entire expression.

${name:*arrayname}

Similar to the preceding substitution, but in the opposite sense, so that entries present in both the original substitution and as elements of arrayname are retained and others removed.

${name:^arrayname}

${name:^^arrayname}

Zips two arrays, such that the output array is twice as long as the shortest (longest for `:^^') of name and arrayname, with the elements alternatingly being picked from them. For `:^', if one of the input arrays is longer, the output will stop when the end of the shorter array is reached. Thus,

a=(1 2 3 4); b=(a b); print ${a:^b}

a=(a b); b=(1 2); print -l "${a:^b}"; print -l "${${a:^b}}"

${name:offset}

${name:offset:length}

This syntax gives effects similar to parameter subscripting in the form $name[start,end], but is compatible with other shells; note that both offset and length are interpreted differently from the components of a subscript.

print ${foo:3}
print ${foo: 1 + 2}
print ${foo:$(( 1 + 2))}
print ${foo:$(echo 1 + 2)}

${name/pattern/repl}

${name//pattern/repl}

${name:/pattern/repl}

Replace the longest possible match of pattern in the expansion of parameter name by string repl. The first form replaces just the first occurrence, the second form all occurrences, and the third form replaces only if pattern matches the entire string. Both pattern and repl are subject to double-quoted substitution, so that expressions like ${name/$opat/$npat} will work, but obey the usual rule that pattern characters in $opat are not treated specially unless either the option GLOB_SUBST is set, or $opat is instead substituted as ${~opat}.

foo="twinkle twinkle little star" sub="t*e" rep="spy"
print ${foo//${~sub}/$rep}
print ${(S)foo//${~sub}/$rep}

${#spec}

If spec is one of the above substitutions, substitute the length in characters of the result instead of the result itself. If spec is an array expression, substitute the number of elements of the result. This has the side-effect that joining is skipped even in quoted forms, which may affect other sub-expressions in spec. Note that `^', `=', and `~', below, must appear to the left of `#' when these forms are combined.

${^spec}

${^^spec}

Turn on the RC_EXPAND_PARAM option for the evaluation of spec; if the `^' is doubled, turn it off. When this option is set, array expansions of the form foo${xx}bar, where the parameter xx is set to (a b c), are substituted with `fooabar foobbar foocbar' instead of the default `fooa b cbar'. Note that an empty array will therefore cause all arguments to be removed.

${=spec}

${==spec}

Perform word splitting using the rules for SH_WORD_SPLIT during the evaluation of spec, but regardless of whether the parameter appears in double quotes; if the `=' is doubled, turn it off. This forces parameter expansions to be split into separate words before substitution, using IFS as a delimiter. This is done by default in most other shells.

${~spec}

${~~spec}

Turn on the GLOB_SUBST option for the evaluation of spec; if the `~' is doubled, turn it off. When this option is set, the string resulting from the expansion will be interpreted as a pattern anywhere that is possible, such as in filename expansion and filename generation and pattern-matching contexts like the right hand side of the `=' and `!=' operators in conditions.

If a ${...} type parameter expression or a $(...) type command substitution is used in place of name above, it is expanded first and the result is used as if it were the value of name. Thus it is possible to perform nested operations: ${${foo#head}%tail} substitutes the value of $foo with both `head' and `tail' deleted. The form with $(...) is often useful in combination with the flags described next; see the examples below. Each name or nested ${...} in a parameter expansion may also be followed by a subscript expression as described in Array Parameters in zshparam(1).

Note that double quotes may appear around nested expressions, in which case only the part inside is treated as quoted; for example, ${(f)"$(foo)"} quotes the result of $(foo), but the flag `(f)' (see below) is applied using the rules for unquoted expansions. Note further that quotes are themselves nested in this context; for example, in "${(@f)"$(foo)"}", there are two sets of quotes, one surrounding the whole expression, the other (redundant) surrounding the $(foo) as before.

pattern=${(q)str}
[[ $str = ${~pattern} ]]

pattern=${(b)str}
[[ $str = ${~pattern} ]]

sep=:
val=a:b:c
print ${(ps.$sep.)val}

[[ "?" = ${(~j.|.)array} ]]

line="one::three"
print -l "${(s.:.)line}"

% str="aXbXc"
% echo ${(S)str#X*}
abXc
% echo ${(S)str##X*}
a
% 

% str="aXbXc"
% echo ${(S)str%X*}
aXbc
% echo ${(S)str%%X*}
aXb
% 

% str="abab"
% echo ${str/*b/_}
_
% echo ${(S)str/*b/_}
_ab
% 

which switch is the right switch for Ipswich?

COMMAND SUBSTITUTION

A command enclosed in parentheses preceded by a dollar sign, like `$(...)', or quoted with grave accents, like ``...`', is replaced with its standard output, with any trailing newlines deleted. If the substitution is not enclosed in double quotes, the output is broken into words using the IFS parameter.

The substitution `$(cat foo)' may be replaced by the faster `$(<foo)'. In this case foo undergoes single word shell expansions (parameter expansion, command substitution and arithmetic expansion), but not filename generation.

If the option GLOB_SUBST is set, the result of any unquoted command substitution, including the special form just mentioned, is eligible for filename generation.

ARITHMETIC EXPANSION

A string of the form `$[exp]' or `$((exp))' is substituted with the value of the arithmetic expression exp. exp is subjected to parameter expansion, command substitution and arithmetic expansion before it is evaluated. See the section `Arithmetic Evaluation'.

BRACE EXPANSION

A string of the form `foo{xx,yy,zz}bar' is expanded to the individual words `fooxxbar', `fooyybar' and `foozzbar'. Left-to-right order is preserved. This construct may be nested. Commas may be quoted in order to include them literally in a word.

An expression of the form `{n1..n2}', where n1 and n2 are integers, is expanded to every number between n1 and n2 inclusive. If either number begins with a zero, all the resulting numbers will be padded with leading zeroes to that minimum width, but for negative numbers the - character is also included in the width. If the numbers are in decreasing order the resulting sequence will also be in decreasing order.

An expression of the form `{n1..n2..n3}', where n1, n2, and n3 are integers, is expanded as above, but only every n3th number starting from n1 is output. If n3 is negative the numbers are output in reverse order, this is slightly different from simply swapping n1 and n2 in the case that the step n3 doesn't evenly divide the range. Zero padding can be specified in any of the three numbers, specifying it in the third can be useful to pad for example `{-99..100..01}' which is not possible to specify by putting a 0 on either of the first two numbers (i.e. pad to two characters).

An expression of the form `{c1..c2}', where c1 and c2 are single characters (which may be multibyte characters), is expanded to every character in the range from c1 to c2 in whatever character sequence is used internally. For characters with code points below 128 this is US ASCII (this is the only case most users will need). If any intervening character is not printable, appropriate quotation is used to render it printable. If the character sequence is reversed, the output is in reverse order, e.g. `{d..a}' is substituted as `d c b a'.

If a brace expression matches none of the above forms, it is left unchanged, unless the option BRACE_CCL (an abbreviation for `brace character class') is set. In that case, it is expanded to a list of the individual characters between the braces sorted into the order of the characters in the ASCII character set (multibyte characters are not currently handled). The syntax is similar to a [...] expression in filename generation: `-' is treated specially to denote a range of characters, but `^' or `!' as the first character is treated normally. For example, `{abcdef0-9}' expands to 16 words 0 1 2 3 4 5 6 7 8 9 a b c d e f.

Note that brace expansion is not part of filename generation (globbing); an expression such as */{foo,bar} is split into two separate words */foo and */bar before filename generation takes place. In particular, note that this is liable to produce a `no match' error if either of the two expressions does not match; this is to be contrasted with */(foo|bar), which is treated as a single pattern but otherwise has similar effects.

To combine brace expansion with array expansion, see the ${^spec} form described in the section `Parameter Expansion' above.

FILENAME EXPANSION

Each word is checked to see if it begins with an unquoted `~'. If it does, then the word up to a `/', or the end of the word if there is no `/', is checked to see if it can be substituted in one of the ways described here. If so, then the `~' and the checked portion are replaced with the appropriate substitute value.

A `~' by itself is replaced by the value of $HOME. A `~' followed by a `+' or a `-' is replaced by current or previous working directory, respectively.

A `~' followed by a number is replaced by the directory at that position in the directory stack. `~0' is equivalent to `~+', and `~1' is the top of the stack. `~+' followed by a number is replaced by the directory at that position in the directory stack. `~+0' is equivalent to `~+', and `~+1' is the top of the stack. `~-' followed by a number is replaced by the directory that many positions from the bottom of the stack. `~-0' is the bottom of the stack. The PUSHD_MINUS option exchanges the effects of `~+' and `~-' where they are followed by a number.

reply=(s 16)

zsh_directory_name() {
  emulate -L zsh
  setopt extendedglob
  local -a match mbegin mend
  if [[ $1 = d ]]; then
    # turn the directory into a name
    if [[ $2 = (#b)(/home/pws/perforce/)([^/]##)* ]]; then
      typeset -ga reply
      reply=(p:$match[2] $(( ${#match[1]} + ${#match[2]} )) )
    else
      return 1
    fi
  elif [[ $1 = n ]]; then
    # turn the name into a directory
    [[ $2 != (#b)p:(?*) ]] && return 1
    typeset -ga reply
    reply=(/home/pws/perforce/$match[1])
  elif [[ $1 = c ]]; then
    # complete names
    local expl
    local -a dirs
    dirs=(/home/pws/perforce/*(/:t))
    dirs=(p:${^dirs})
    _wanted dynamic-dirs expl 'dynamic directory' compadd -S\] -a dirs
    return
  else
    return 1
  fi
  return 0
}

FILENAME GENERATION

If a word contains an unquoted instance of one of the characters `*', `(', `|', `<', `[', or `?', it is regarded as a pattern for filename generation, unless the GLOB option is unset. If the EXTENDED_GLOB option is set, the `^' and `#' characters also denote a pattern; otherwise they are not treated specially by the shell.

The word is replaced with a list of sorted filenames that match the pattern. If no matching pattern is found, the shell gives an error message, unless the NULL_GLOB option is set, in which case the word is deleted; or unless the NOMATCH option is unset, in which case the word is left unchanged.

In filename generation, the character `/' must be matched explicitly; also, a `.' must be matched explicitly at the beginning of a pattern or after a `/', unless the GLOB_DOTS option is set. No filename generation pattern matches the files `.' or `..'. In other instances of pattern matching, the `/' and `.' are not treated specially.

foo="a_string_with_a_message"
if [[ $foo = (a|an)_(#b)(*) ]]; then
  print ${foo[$mbegin[1],$mend[1]]}
fi

arr=(veldt jynx grimps waqf zho buck)
print ${arr//(#m)[aeiou]/${(U)MATCH}}

ls -ld -- (*/)#bar

ls -ld -- **/bar

setopt GLOBSTARSHORT
ls -ld -- **.c

ls -ld -- **/*.c

nt() { [[ $REPLY -nt $NTREF ]] }
NTREF=reffile
ls -ld -- *(+nt)

ls -ld -- *(-/)

ls -ld -- *(-@)

ls -ld -- *(%W)

ls -ld -- *(W,X)

print -rC1 /tmp/foo*(u0^@:t)

ls -ld -- *.*~(lex|parse).[ch](^D^l1)

print -rC1 b*.pro(#q:s/pro/shmo/)(#q.:s/builtin/shmiltin/)

NAME

zshparam - zsh parameters

DESCRIPTION

A parameter has a name, a value, and a number of attributes. A name may be any sequence of alphanumeric characters and underscores, or the single characters `*', `@', `#', `?', `-', `$', or `!'. A parameter whose name begins with an alphanumeric or underscore is also referred to as a variable.

The attributes of a parameter determine the type of its value, often referred to as the parameter type or variable type, and also control other processing that may be applied to the value when it is referenced. The value type may be a scalar (a string, an integer, or a floating point number), an array (indexed numerically), or an associative array (an unordered set of name-value pairs, indexed by name, also referred to as a hash).

Named scalar parameters may have the exported, -x, attribute, to copy them into the process environment, which is then passed from the shell to any new processes that it starts. Exported parameters are called environment variables. The shell also imports environment variables at startup time and automatically marks the corresponding parameters as exported. Some environment variables are not imported for reasons of security or because they would interfere with the correct operation of other shell features.

Parameters may also be special, that is, they have a predetermined meaning to the shell. Special parameters cannot have their type changed or their readonly attribute turned off, and if a special parameter is unset, then later recreated, the special properties will be retained.

To declare the type of a parameter, or to assign a string or numeric value to a scalar parameter, use the typeset builtin.

The value of a scalar parameter may also be assigned by writing:

name=value

In scalar assignment, value is expanded as a single string, in which the elements of arrays are joined together; filename expansion is not performed unless the option GLOB_ASSIGN is set.

When the integer attribute, -i, or a floating point attribute, -E or -F, is set for name, the value is subject to arithmetic evaluation. Furthermore, by replacing `=' with `+=', a parameter can be incremented or appended to. See the section `Array Parameters' and Arithmetic Evaluation (in zshmisc(1)) for additional forms of assignment.

Note that assignment may implicitly change the attributes of a parameter. For example, assigning a number to a variable in arithmetic evaluation may change its type to integer or float, and with GLOB_ASSIGN assigning a pattern to a variable may change its type to an array.

To reference the value of a parameter, write `$name' or `${name}'. See Parameter Expansion in zshexpn(1) for complete details. That section also explains the effect of the difference between scalar and array assignment on parameter expansion.

ARRAY PARAMETERS

To assign an array value, write one of:

set -A name value ...

name=(value ...)

name=([key]=value ...)

If no parameter name exists, an ordinary array parameter is created. If the parameter name exists and is a scalar, it is replaced by a new array.

In the third form, key is an expression that will be evaluated in arithmetic context (in its simplest form, an integer) that gives the index of the element to be assigned with value. In this form any elements not explicitly mentioned that come before the largest index to which a value is assigned are assigned an empty string. The indices may be in any order. Note that this syntax is strict: [ and ]= must not be quoted, and key may not consist of the unquoted string ]=, but is otherwise treated as a simple string. The enhanced forms of subscript expression that may be used when directly subscripting a variable name, described in the section `Array Subscripts' below, are not available.

The syntaxes with and without the explicit key may be mixed. An implicit key is deduced by incrementing the index from the previously assigned element. Note that it is not treated as an error if latter assignments in this form overwrite earlier assignments.

For example, assuming the option KSH_ARRAYS is not set, the following:

array=(one [3]=three four)

causes the array variable array to contain four elements one, an empty string, three and four, in that order.

In the forms where only value is specified, full command line expansion is performed.

In the [key]=value form, both key and value undergo all forms of expansion allowed for single word shell expansions (this does not include filename generation); these are as performed by the parameter expansion flag (e) as described in zshexpn(1). Nested parentheses may surround value and are included as part of the value, which is joined into a plain string; this differs from ksh which allows the values themselves to be arrays. A future version of zsh may support that. To cause the brackets to be interpreted as a character class for filename generation, and therefore to treat the resulting list of files as a set of values, quote the equal sign using any form of quoting. Example:

name=([a-z]'='*)

To append to an array without changing the existing values, use one of the following:

name+=(value ...)

name+=([key]=value ...)

In the second form key may specify an existing index as well as an index off the end of the old array; any existing value is overwritten by value. Also, it is possible to use [key]+=value to append to the existing value at that index.

Within the parentheses on the right hand side of either form of the assignment, newlines and semicolons are treated the same as white space, separating individual values. Any consecutive sequence of such characters has the same effect.

Ordinary array parameters may also be explicitly declared with:

typeset -a name

Associative arrays must be declared before assignment, by using:

typeset -A name

When name refers to an associative array, the list in an assignment is interpreted as alternating keys and values:

set -A name key value ...

name=(key value ...)

name=([key]=value ...)

Note that only one of the two syntaxes above may be used in any given assignment; the forms may not be mixed. This is unlike the case of numerically indexed arrays.

Every key must have a value in this case. Note that this assigns to the entire array, deleting any elements that do not appear in the list. The append syntax may also be used with an associative array:

name+=(key value ...)

name+=([key]=value ...)

This adds a new key/value pair if the key is not already present, and replaces the value for the existing key if it is. In the second form it is also possible to use [key]+=value to append to the existing value at that key. Expansion is performed identically to the corresponding forms for normal arrays, as described above.

To create an empty array (including associative arrays), use one of:

set -A name

name=()

string="abcdefghijklm"
print ${string[(r)d?,(r)h?]}

name[exp]=value

typeset "name[exp]"=value

unset "name[exp]"

[[ ${array[(i)pattern]} -le ${#array} ]]

key2='original key'
print ${array[(Re)$key2]}

aa+=('key with "*strange*" characters' 'value string')

typeset -A aa
typeset "aa[one\"two\"three\"quotes]"=QQQ
print "$aa[one\"two\"three\"quotes]"

typeset -A aa
aa[(e)*]=star
print $aa[(e)*]

POSITIONAL PARAMETERS

The positional parameters provide access to the command-line arguments of a shell function, shell script, or the shell itself; see the section `Invocation', and also the section `Functions'. The parameter n, where n is a number, is the nth positional parameter. The parameter `$0' is a special case, see the section `Parameters Set By The Shell'.

The parameters *, @ and argv are arrays containing all the positional parameters; thus `$argv[n]', etc., is equivalent to simply `$n'. Note that the options KSH_ARRAYS or KSH_ZERO_SUBSCRIPT apply to these arrays as well, so with either of those options set, `${argv[0]}' is equivalent to `$1' and so on.

Positional parameters may be changed after the shell or function starts by using the set builtin, by assigning to the argv array, or by direct assignment of the form `n=value' where n is the number of the positional parameter to be changed. This also creates (with empty values) any of the positions from 1 to n that do not already have values. Note that, because the positional parameters form an array, an array assignment of the form `n=(value ...)' is allowed, and has the effect of shifting all the values at positions greater than n by as many positions as necessary to accommodate the new values.

LOCAL PARAMETERS

Shell function executions delimit scopes for shell parameters. (Parameters are dynamically scoped.) The typeset builtin, and its alternative forms declare, integer, local and readonly (but not export), can be used to declare a parameter as being local to the innermost scope.

When a parameter is read or assigned to, the innermost existing parameter of that name is used. (That is, the local parameter hides any less-local parameter.) However, assigning to a non-existent parameter, or declaring a new parameter with export, causes it to be created in the outermost scope.

Local parameters disappear when their scope ends. unset can be used to delete a parameter while it is still in scope; any outer parameter of the same name remains hidden.

Special parameters may also be made local; they retain their special attributes unless either the existing or the newly-created parameter has the -h (hide) attribute. This may have unexpected effects: there is no default value, so if there is no assignment at the point the variable is made local, it will be set to an empty value (or zero in the case of integers). The following:

typeset PATH=/new/directory:$PATH

is valid for temporarily allowing the shell or programmes called from it to find the programs in /new/directory inside a function.

Note that the restriction in older versions of zsh that local parameters were never exported has been removed.

PARAMETERS SET BY THE SHELL

In the parameter lists that follow, the mark `<S>' indicates that the parameter is special. `<Z>' indicates that the parameter does not exist when the shell initializes in sh or ksh emulation mode.

The parameters `!', `#', `*', `-', `?', `@', `$', `ARGC', `HISTCMD', `LINENO', `PPID', `status', `TTYIDLE', `zsh_eval_context', `ZSH_EVAL_CONTEXT', and `ZSH_SUBSHELL' are read-only and thus cannot be restored by the user, so they are not output by `typeset -p'. This also applies to many read-only parameters loaded from modules.

The following parameters are automatically set by the shell:

! <S>

The process ID of the last command started in the background with &, put into the background with the bg builtin, or spawned with coproc.

# <S>

The number of positional parameters in decimal. Note that some confusion may occur with the syntax $#param which substitutes the length of param. Use ${#} to resolve ambiguities. In particular, the sequence `$#-...' in an arithmetic expression is interpreted as the length of the parameter -, q.v.

ARGC <S> <Z>

Same as #.

$ <S>

The process ID of this shell, set when the shell initializes. Processes forked from the shell without executing a new program, such as command substitutions and commands grouped with (...), are subshells that duplicate the current shell, and thus substitute the same value for $$ as their parent shell.

- <S>

Flags supplied to the shell on invocation or by the set or setopt commands.

* <S>

An array containing the positional parameters.

argv <S> <Z>

Same as *. Assigning to argv changes the local positional parameters, but argv is not itself a local parameter. Deleting argv with unset in any function deletes it everywhere, although only the innermost positional parameter array is deleted (so * and @ in other scopes are not affected).

@ <S>

Same as argv[@], even when argv is not set.

? <S>

The exit status returned by the last command.

0 <S>

The name used to invoke the current shell, or as set by the -c command line option upon invocation. If the FUNCTION_ARGZERO option is set, $0 is set upon entry to a shell function to the name of the function, and upon entry to a sourced script to the name of the script, and reset to its previous value when the function or script returns.

status <S> <Z>

Same as ?.

pipestatus <S> <Z>

An array containing the exit statuses returned by all commands in the last pipeline.

_ <S>

The last argument of the previous command. Also, this parameter is set in the environment of every command executed to the full pathname of the command.

CPUTYPE

The machine type (microprocessor class or machine model), as determined at run time.

EGID <S>

The effective group ID of the shell process. If you have sufficient privileges, you may change the effective group ID of the shell process by assigning to this parameter. Also (assuming sufficient privileges), you may start a single command with a different effective group ID by `(EGID=gid; command)'

EUID <S>

The effective user ID of the shell process. If you have sufficient privileges, you may change the effective user ID of the shell process by assigning to this parameter. Also (assuming sufficient privileges), you may start a single command with a different effective user ID by `(EUID=uid; command)'

ERRNO <S>

The value of errno (see errno(3)) as set by the most recently failed system call. This value is system dependent and is intended for debugging purposes. It is also useful with the zsh/system module which allows the number to be turned into a name or message.

FUNCNEST <S>

Integer. If greater than or equal to zero, the maximum nesting depth of shell functions. When it is exceeded, an error is raised at the point where a function is called. The default value is determined when the shell is configured, but is typically 500. Increasing the value increases the danger of a runaway function recursion causing the shell to crash. Setting a negative value turns off the check.

GID <S>

The real group ID of the shell process. If you have sufficient privileges, you may change the group ID of the shell process by assigning to this parameter. Also (assuming sufficient privileges), you may start a single command under a different group ID by `(GID=gid; command)'

HISTCMD

The current history event number in an interactive shell, in other words the event number for the command that caused $HISTCMD to be read. If the current history event modifies the history, HISTCMD changes to the new maximum history event number.

HOST

The current hostname.

LINENO <S>

The line number of the current line within the current script, sourced file, or shell function being executed, whichever was started most recently. Note that in the case of shell functions the line number refers to the function as it appeared in the original definition, not necessarily as displayed by the functions builtin.

LOGNAME

If the corresponding variable is not set in the environment of the shell, it is initialized to the login name corresponding to the current login session. This parameter is exported by default but this can be disabled using the typeset builtin. The value is set to the string returned by the getlogin(3) system call if that is available.

MACHTYPE

The machine type (microprocessor class or machine model), as determined at compile time.

OLDPWD

The previous working directory. This is set when the shell initializes and whenever the directory changes.

OPTARG <S>

The value of the last option argument processed by the getopts command.

OPTIND <S>

The index of the last option argument processed by the getopts command.

OSTYPE

The operating system, as determined at compile time.

PPID <S>

The process ID of the parent of the shell, set when the shell initializes. As with $$, the value does not change in subshells created as a duplicate of the current shell.

PWD

The present working directory. This is set when the shell initializes and whenever the directory changes.

RANDOM <S>

A pseudo-random integer from 0 to 32767, newly generated each time this parameter is referenced. The random number generator can be seeded by assigning a numeric value to RANDOM.

SECONDS <S>

The number of seconds since shell invocation. If this parameter is assigned a value, then the value returned upon reference will be the value that was assigned plus the number of seconds since the assignment.

SHLVL <S>

Incremented by one each time a new shell is started.

signals

An array containing the names of the signals. Note that with the standard zsh numbering of array indices, where the first element has index 1, the signals are offset by 1 from the signal number used by the operating system. For example, on typical Unix-like systems HUP is signal number 1, but is referred to as $signals[2]. This is because of EXIT at position 1 in the array, which is used internally by zsh but is not known to the operating system.

TRY_BLOCK_ERROR <S>

In an always block, indicates whether the preceding list of code caused an error. The value is 1 to indicate an error, 0 otherwise. It may be reset, clearing the error condition. See Complex Commands in zshmisc(1)

TRY_BLOCK_INTERRUPT <S>

This variable works in a similar way to TRY_BLOCK_ERROR, but represents the status of an interrupt from the signal SIGINT, which typically comes from the keyboard when the user types ^C. If set to 0, any such interrupt will be reset; otherwise, the interrupt is propagated after the always block.