STAPEX(3stap)                                                    STAPEX(3stap)

JMENO
       stapex - priklady



ZAKLADY SKRIPTOVACIHO JAZYKA
       Nasledujici priklady demonstruji zaklady syntaxe a ridicich struktur
       skriptovaciho jazyka systemtapu.


              global odds, evens

              probe begin {
                # "no" and "ne" are local integers
                for (i=0; i<10; i++) {
                  if (i % 2) odds [no++] = i
                  else evens [ne++] = i
                }
                delete odds[2]
                delete evens[3]
                exit ()
              }

              probe end {
                foreach (x+ in odds) {
                  printf ("odds[%d] = %d\n", x, odds[x])
                }
                foreach (x in evens-) {
                  printf ("evens[%d] = %d\n", x, evens[x])
                }
              }

Vystupem vyse uvedeneho skriptu bude:

              odds[1] = 1
              odds[3] = 5
              odds[4] = 7
              odds[5] = 9
              evens[5] = 8
              evens[4] = 6
              evens[2] = 2
              evens[1] = 0

Poznamenejme, ze datove typy vsech promennych jsou automaticky odvozene, a ze
vsechny globalni promenne jsou automaticky inicializovany.


       Nasledujici skript vypise prvocisla mezi 0 a 49.

              function isprime (x) {
                if (x < 2) return 0
                for (i=2; i<x; i++) {
                  if (x % i == 0) return 0
                  if (i * i > x) break
                }
                return 1
              }
              probe begin {
                for (i=0; i<50; i++)
                  if (isprime (i)) printf("%d\n", i)
                exit()
              }



       Tento skript je ukazkou pouziti rekurzivnich funkci.

              function fibonacci(i) {
                if (i < 1) error ("bad number")
                if (i == 1) return 1
                if (i == 2) return 2
                return fibonacci (i-1) + fibonacci (i-2)
              }
              probe begin {
                printf ("11th fibonacci number: %d\n", fibonacci (11))
                exit ()
              }

Pri pokusu o generovani vetsich cisel bychom narazili na limity MAXACTION,
nebo MAXNESTING a vysledkem by byla chyba.


SONDOVANI
       Pro sledovani vstupu do funkce a vystupu z ni pouzijte nasledujici par
       sond:

              probe kernel.function("sys_mkdir") { println ("enter") }
              probe kernel.function("sys_mkdir").return { println ("exit") }


Pro vypsani jadernych funkci do kterych lze vlozit sondu pouzijte rezim vypisu
-l:


              % stap -l 'kernel.function("*")'


Pro vypis jadernych funkci a v nich pristupnych lokalnich promennych pouzijte
rezim vypisu -L:


              % stap -L 'kernel.function("*")'



VICE PRIKLADU
       Adresar s priklady je zminen v manualove strance stappaths (7),
       pripadne online na adrese: http://sourceware.org/systemtap/examples/


VIZ TEZ
       stap(1)
       stapprobes(3stap)
       stappaths(7)


                                                                 STAPEX(3stap)