Simple options

The most simple options are the ones that take no values. Their mere presence on the command line enables the option. Popular examples are:

--all --verbose --quiet --debug

Handling simple options is straightforward:

my $verbose = '';   # option variable with default value (false)
my $all = '';       # option variable with default value (false)
GetOptions ('verbose' => \$verbose, 'all' => \$all);

The call to GetOptions() parses the command line arguments that are present in @ARGV and sets the option variable to the value 1 if the option did occur on the command line. Otherwise, the option variable is not touched. Setting the option value to true is often called enabling the option.

The option name as specified to the GetOptions() function is called the option specification. Later we'll see that this specification can contain more than just the option name. The reference to the variable is called the option destination.

GetOptions() will return a true value if the command line could be processed successfully. Otherwise, it will write error messages using die() and warn(), and return a false result.

A little bit less simple options

Getopt::Long supports two useful variants of simple options: negatable options and incremental options.

A negatable option is specified with an exclamation mark "!" after the option name:

my $verbose = '';   # option variable with default value (false)
GetOptions ('verbose!' => \$verbose);

Now, using "--verbose" on the command line will enable $verbose, as expected. But it is also allowed to use "--noverbose", which will disable $verbose by setting its value to 0. Using a suitable default value, the program can find out whether $verbose is false by default, or disabled by using "--noverbose".

(If both "--verbose" and "--noverbose" are given, whichever is given last takes precedence.)

An incremental option is specified with a plus "+" after the option name:

my $verbose = '';   # option variable with default value (false)
GetOptions ('verbose+' => \$verbose);

Using "--verbose" on the command line will increment the value of $verbose. This way the program can keep track of how many times the option occurred on the command line. For example, each occurrence of "--verbose" could increase the verbosity level of the program.

Mixing command line option with other arguments

Usually programs take command line options as well as other arguments, for example, file names. It is good practice to always specify the options first, and the other arguments last. Getopt::Long will, however, allow the options and arguments to be mixed and 'filter out' all the options before passing the rest of the arguments to the program. To stop Getopt::Long from processing further arguments, insert a double dash "--" on the command line:

--size 24 -- --all

In this example, "--all" will not be treated as an option, but passed to the program unharmed, in @ARGV.

Options with values

For options that take values it must be specified whether the option value is required or not, and what kind of value the option expects.

Three kinds of values are supported: integer numbers, floating point numbers, and strings.

If the option value is required, Getopt::Long will take the command line argument that follows the option and assign this to the option variable. If, however, the option value is specified as optional, this will only be done if that value does not look like a valid command line option itself.

my $tag = '';       # option variable with default value
GetOptions ('tag=s' => \$tag);

In the option specification, the option name is followed by an equals sign "=" and the letter "s". The equals sign indicates that this option requires a value. The letter "s" indicates that this value is an arbitrary string. Other possible value types are "i" for integer values, and "f" for floating point values. Using a colon ":" instead of the equals sign indicates that the option value is optional. In this case, if no suitable value is supplied, string valued options get an empty string '' assigned, while numeric options are set to 0.

(If the same option appears more than once on the command line, the last given value is used. If you want to take all the values, see below.)

Options with multiple values

Options sometimes take several values. For example, a program could use multiple directories to search for library files:

--library lib/stdlib --library lib/extlib

To accomplish this behaviour, simply specify an array reference as the destination for the option:

GetOptions ("library=s" => \@libfiles);

Alternatively, you can specify that the option can have multiple values by adding a "@", and pass a reference to a scalar as the destination:

GetOptions ("library=s@" => \$libfiles);

Used with the example above, @libfiles c.q. @$libfiles would contain two strings upon completion: "lib/stdlib" and "lib/extlib", in that order. It is also possible to specify that only integer or floating point numbers are acceptable values.

Often it is useful to allow comma-separated lists of values as well as multiple occurrences of the options. This is easy using Perl's split() and join() operators:

GetOptions ("library=s" => \@libfiles);
@libfiles = split(/,/,join(',',@libfiles));

Of course, it is important to choose the right separator string for each purpose.

Warning: What follows is an experimental feature.

Options can take multiple values at once, for example

--coordinates 52.2 16.4 --rgbcolor 255 255 149

This can be accomplished by adding a repeat specifier to the option specification. Repeat specifiers are very similar to the "{...}" repeat specifiers that can be used with regular expression patterns. For example, the above command line would be handled as follows:

GetOptions('coordinates=f{2}' => \@coor, 'rgbcolor=i{3}' => \@color);

The destination for the option must be an array or array reference.

It is also possible to specify the minimal and maximal number of arguments an option takes. "foo=s{2,4}" indicates an option that takes at least two and at most 4 arguments. "foo=s{1,}" indicates one or more values; "foo:s{,}" indicates zero or more option values.

Options with hash values

If the option destination is a reference to a hash, the option will take, as value, strings of the form key"="value. The value will be stored with the specified key in the hash.

GetOptions ("define=s" => \%defines);

Alternatively you can use:

GetOptions ("define=s%" => \$defines);

When used with command line options:

--define os=linux --define vendor=redhat

the hash %defines (or %$defines) will contain two keys, "os" with value "linux" and "vendor" with value "redhat". It is also possible to specify that only integer or floating point numbers are acceptable values. The keys are always taken to be strings.

User-defined subroutines to handle options

Ultimate control over what should be done when (actually: each time) an option is encountered on the command line can be achieved by designating a reference to a subroutine (or an anonymous subroutine) as the option destination. When GetOptions() encounters the option, it will call the subroutine with two or three arguments. The first argument is the name of the option. (Actually, it is an object that stringifies to the name of the option.) For a scalar or array destination, the second argument is the value to be stored. For a hash destination, the second argument is the key to the hash, and the third argument the value to be stored. It is up to the subroutine to store the value, or do whatever it thinks is appropriate.

A trivial application of this mechanism is to implement options that are related to each other. For example:

my $verbose = '';   # option variable with default value (false)
GetOptions ('verbose' => \$verbose,
            'quiet'   => sub { $verbose = 0 });

Here "--verbose" and "--quiet" control the same variable $verbose, but with opposite values.

If the subroutine needs to signal an error, it should call die() with the desired error message as its argument. GetOptions() will catch the die(), issue the error message, and record that an error result must be returned upon completion.

If the text of the error message starts with an exclamation mark "!" it is interpreted specially by GetOptions(). There is currently one special command implemented: die("!FINISH") will cause GetOptions() to stop processing options, as if it encountered a double dash "--".

Here is an example of how to access the option name and value from within a subroutine:

GetOptions ('opt=i' => \&handler);
sub handler {
    my ($opt_name, $opt_value) = @_;
    print("Option name is $opt_name and value is $opt_value\n");
}

Options with multiple names

Often it is user friendly to supply alternate mnemonic names for options. For example "--height" could be an alternate name for "--length". Alternate names can be included in the option specification, separated by vertical bar "|" characters. To implement the above example:

GetOptions ('length|height=f' => \$length);

The first name is called the primary name, the other names are called aliases. When using a hash to store options, the key will always be the primary name.

Multiple alternate names are possible.

Case and abbreviations

Without additional configuration, GetOptions() will ignore the case of option names, and allow the options to be abbreviated to uniqueness.

GetOptions ('length|height=f' => \$length, "head" => \$head);

This call will allow "--l" and "--L" for the length option, but requires a least "--hea" and "--hei" for the head and height options.

Summary of Option Specifications

Each option specifier consists of two parts: the name specification and the argument specification.

The name specification contains the name of the option, optionally followed by a list of alternative names separated by vertical bar characters. The name is made up of alphanumeric characters, hyphens, underscores. If "pass_through" is disabled, a period is also allowed in option names.

length            option name is "length"
length|size|l     name is "length", aliases are "size" and "l"

The argument specification is optional. If omitted, the option is considered boolean, a value of 1 will be assigned when the option is used on the command line.

The argument specification can be

!

The option does not take an argument and may be negated by prefixing it with "no" or "no-". E.g. "foo!" will allow "--foo" (a value of 1 will be assigned) as well as "--nofoo" and "--no-foo" (a value of 0 will be assigned). If the option has aliases, this applies to the aliases as well.

Using negation on a single letter option when bundling is in effect is pointless and will result in a warning.

+

The option does not take an argument and will be incremented by 1 every time it appears on the command line. E.g. "more+", when used with "--more --more --more", will increment the value three times, resulting in a value of 3 (provided it was 0 or undefined at first).

The "+" specifier is ignored if the option destination is not a scalar.

= type [ desttype ] [ repeat ]

The option requires an argument of the given type. Supported types are:

: type [ desttype ]

Like "=", but designates the argument as optional. If omitted, an empty string will be assigned to string values options, and the value zero to numeric options.

Note that if a string argument starts with "-" or "--", it will be considered an option on itself.

: number [ desttype ]

Like ":i", but if the value is omitted, the number will be assigned.

If the number is octal, hexadecimal or binary, behaves like ":o".

: + [ desttype ]

Like ":i", but if the value is omitted, the current value for the option will be incremented.

Object oriented interface

See Getopt::Long::Parser.

Callback object

In version 2.37 the first argument to the callback function was changed from string to object. This was done to make room for extensions and more detailed control. The object stringifies to the option name so this change should not introduce compatibility problems.

The callback object has the following methods:

name

The name of the option, unabbreviated. For an option with multiple names it return the first (canonical) name.

given

The name of the option as actually used, unabbreveated.

Thread Safety

Getopt::Long is thread safe when using ithreads as of Perl 5.8. It is not thread safe when using the older (experimental and now obsolete) threads implementation that was added to Perl 5.005.

Documentation and help texts

Getopt::Long encourages the use of Pod::Usage to produce help messages. For example:

use Getopt::Long;
use Pod::Usage;
my $man = 0;
my $help = 0;
GetOptions('help|?' => \$help, man => \$man) or pod2usage(2);
pod2usage(1) if $help;
pod2usage(-exitval => 0, -verbose => 2) if $man;
__END__
=head1 NAME
sample - Using Getopt::Long and Pod::Usage
=head1 SYNOPSIS
sample [options] [file ...]
 Options:
   -help            brief help message
   -man             full documentation
=head1 OPTIONS
=over 8
=item B<-help>
Print a brief help message and exits.
=item B<-man>
Prints the manual page and exits.
=back
=head1 DESCRIPTION
B<This program> will read the given input file(s) and do something
useful with the contents thereof.
=cut

See Pod::Usage for details.

Parsing options from an arbitrary array

By default, GetOptions parses the options that are present in the global array @ARGV. A special entry "GetOptionsFromArray" can be used to parse options from an arbitrary array.

use Getopt::Long qw(GetOptionsFromArray);
$ret = GetOptionsFromArray(\@myopts, ...);

When used like this, options and their possible values are removed from @myopts, the global @ARGV is not touched at all.

The following two calls behave identically:

$ret = GetOptions( ... );
$ret = GetOptionsFromArray(\@ARGV, ... );

This also means that a first argument hash reference now becomes the second argument:

$ret = GetOptions(\%opts, ... );
$ret = GetOptionsFromArray(\@ARGV, \%opts, ... );

Parsing options from an arbitrary string

A special entry "GetOptionsFromString" can be used to parse options from an arbitrary string.

use Getopt::Long qw(GetOptionsFromString);
$ret = GetOptionsFromString($string, ...);

The contents of the string are split into arguments using a call to "Text::ParseWords::shellwords". As with "GetOptionsFromArray", the global @ARGV is not touched.

It is possible that, upon completion, not all arguments in the string have been processed. "GetOptionsFromString" will, when called in list context, return both the return status and an array reference to any remaining arguments:

($ret, $args) = GetOptionsFromString($string, ... );

If any arguments remain, and "GetOptionsFromString" was not called in list context, a message will be given and "GetOptionsFromString" will return failure.

As with GetOptionsFromArray, a first argument hash reference now becomes the second argument. See the next section.

Storing options values in a hash

Sometimes, for example when there are a lot of options, having a separate variable for each of them can be cumbersome. GetOptions() supports, as an alternative mechanism, storing options values in a hash.

To obtain this, a reference to a hash must be passed as the first argument to GetOptions(). For each option that is specified on the command line, the option value will be stored in the hash with the option name as key. Options that are not actually used on the command line will not be put in the hash, on other words, exists($h{option}) (or defined()) can be used to test if an option was used. The drawback is that warnings will be issued if the program runs under "use strict" and uses $h{option} without testing with exists() or defined() first.

my %h = ();
GetOptions (\%h, 'length=i');       # will store in $h{length}

For options that take list or hash values, it is necessary to indicate this by appending an "@" or "%" sign after the type:

GetOptions (\%h, 'colours=s@');     # will push to @{$h{colours}}

To make things more complicated, the hash may contain references to the actual destinations, for example:

my $len = 0;
my %h = ('length' => \$len);
GetOptions (\%h, 'length=i');       # will store in $len

This example is fully equivalent with:

my $len = 0;
GetOptions ('length=i' => \$len);   # will store in $len

Any mixture is possible. For example, the most frequently used options could be stored in variables while all other options get stored in the hash:

my $verbose = 0;                    # frequently referred
my $debug = 0;                      # frequently referred
my %h = ('verbose' => \$verbose, 'debug' => \$debug);
GetOptions (\%h, 'verbose', 'debug', 'filter', 'size=i');
if ( $verbose ) { ... }
if ( exists $h{filter} ) { ... option 'filter' was specified ... }

Bundling

With bundling it is possible to set several single-character options at once. For example if "a", "v" and "x" are all valid options,

-vax

will set all three.

Getopt::Long supports three styles of bundling. To enable bundling, a call to Getopt::Long::Configure is required.

The simplest style of bundling can be enabled with:

Getopt::Long::Configure ("bundling");

Configured this way, single-character options can be bundled but long options (and any of their auto-abbreviated shortened forms) must always start with a double dash "--" to avoid ambiguity. For example, when "vax", "a", "v" and "x" are all valid options,

-vax

will set "a", "v" and "x", but

--vax

will set "vax".

The second style of bundling lifts this restriction. It can be enabled with:

Getopt::Long::Configure ("bundling_override");

Now, "-vax" will set the option "vax".

In all of the above cases, option values may be inserted in the bundle. For example:

-h24w80

is equivalent to

-h 24 -w 80

A third style of bundling allows only values to be bundled with options. It can be enabled with:

Getopt::Long::Configure ("bundling_values");

Now, "-h24" will set the option "h" to 24, but option bundles like "-vxa" and "-h24w80" are flagged as errors.

Enabling "bundling_values" will disable the other two styles of bundling.

When configured for bundling, single-character options are matched case sensitive while long options are matched case insensitive. To have the single-character options matched case insensitive as well, use:

Getopt::Long::Configure ("bundling", "ignorecase_always");

It goes without saying that bundling can be quite confusing.

The lonesome dash

Normally, a lone dash "-" on the command line will not be considered an option. Option processing will terminate (unless "permute" is configured) and the dash will be left in @ARGV.

It is possible to get special treatment for a lone dash. This can be achieved by adding an option specification with an empty name, for example:

GetOptions ('' => \$stdio);

A lone dash on the command line will now be a legal option, and using it will set variable $stdio.

Argument callback

A special option 'name' "<>" can be used to designate a subroutine to handle non-option arguments. When GetOptions() encounters an argument that does not look like an option, it will immediately call this subroutine and passes it one parameter: the argument name.

For example:

my $width = 80;
sub process { ... }
GetOptions ('width=i' => \$width, '<>' => \&process);

When applied to the following command line:

arg1 --width=72 arg2 --width=60 arg3

This will call process("arg1") while $width is 80, process("arg2") while $width is 72, and process("arg3") while $width is 60.

This feature requires configuration option permute, see section "Configuring Getopt::Long".

Default destinations

When no destination is specified for an option, GetOptions will store the resultant value in a global variable named "opt_"XXX, where XXX is the primary name of this option. When a program executes under "use strict" (recommended), these variables must be pre-declared with our().

our $opt_length = 0;
GetOptions ('length=i');    # will store in $opt_length

To yield a usable Perl variable, characters that are not part of the syntax for variables are translated to underscores. For example, "--fpp-struct-return" will set the variable $opt_fpp_struct_return. Note that this variable resides in the namespace of the calling program, not necessarily "main". For example:

GetOptions ("size=i", "sizes=i@");

with command line "-size 10 -sizes 24 -sizes 48" will perform the equivalent of the assignments

$opt_size = 10;
@opt_sizes = (24, 48);

Alternative option starters

A string of alternative option starter characters may be passed as the first argument (or the first argument after a leading hash reference argument).

my $len = 0;
GetOptions ('/', 'length=i' => $len);

Now the command line may look like:

/length 24 -- arg

Note that to terminate options processing still requires a double dash "--".

GetOptions() will not interpret a leading "<>" as option starters if the next argument is a reference. To force "<" and ">" as option starters, use "><". Confusing? Well, using a starter argument is strongly deprecated anyway.

Configuration variables

Previous versions of Getopt::Long used variables for the purpose of configuring. Although manipulating these variables still work, it is strongly encouraged to use the "Configure" routine that was introduced in version 2.17. Besides, it is much easier.

Pushing multiple values in a hash option

Sometimes you want to combine the best of hashes and arrays. For example, the command line:

--list add=first --list add=second --list add=third

where each successive 'list add' option will push the value of add into array ref $list->{'add'}. The result would be like

$list->{add} = [qw(first second third)];

This can be accomplished with a destination routine:

GetOptions('list=s%' =>
             sub { push(@{$list{$_[1]}}, $_[2]) });

GetOptions does not return a false result when an option is not supplied

That's why they're called 'options'.

GetOptions does not split the command line correctly

The command line is not split by GetOptions, but by the command line interpreter (CLI). On Unix, this is the shell. On Windows, it is COMMAND.COM or CMD.EXE. Other operating systems have other CLIs.

It is important to know that these CLIs may behave different when the command line contains special characters, in particular quotes or backslashes. For example, with Unix shells you can use single quotes ("'") and double quotes (""") to group words together. The following alternatives are equivalent on Unix:

"two words"
'two words'
two\ words

In case of doubt, insert the following statement in front of your Perl program:

print STDERR (join("|",@ARGV),"\n");

to verify how your CLI passes the arguments to the program.

Undefined subroutine &main::GetOptions called

Are you running Windows, and did you write

use GetOpt::Long;

(note the capital 'O')?

How do I put a "-?" option into a Getopt::Long?

You can only obtain this using an alias, and Getopt::Long of at least version 2.13.

use Getopt::Long;
GetOptions ("help|?");    # -help and -? will both set $opt_help

Other characters that can't appear in Perl identifiers are also supported in aliases with Getopt::Long of at version 2.39. Note that the characters "!", "|", "+", "=", and ":" can only appear as the first (or only) character of an alias.

As of version 2.32 Getopt::Long provides auto-help, a quick and easy way to add the options --help and -? to your program, and handle them.

See "auto_help" in section "Configuring Getopt::Long".