namespace::autoclean(3) User Contributed Perl Documentation namespace::autoclean(3)

namespace::autoclean - Keep imports out of your namespace

version 0.29

package Foo;
use namespace::autoclean;
use Some::Package qw/imported_function/;
sub bar { imported_function('stuff') }
# later on:
Foo->bar;               # works
Foo->imported_function; # will fail. imported_function got cleaned after compilation

When you import a function into a Perl package, it will naturally also be available as a method.

The "namespace::autoclean" pragma will remove all imported symbols at the end of the current package's compile cycle. Functions called in the package itself will still be bound by their name, but they won't show up as methods on your class or instances.

This module is very similar to namespace::clean, except it will clean all imported functions, no matter if you imported them before or after you "use"d the pragma. It will also not touch anything that looks like a method.

If you're writing an exporter and you want to clean up after yourself (and your peers), you can use the "-cleanee" switch to specify what package to clean:

package My::MooseX::namespace::autoclean;
use strict;
use namespace::autoclean (); # no cleanup, just load
sub import {
      -cleanee => scalar(caller),

"namespace::autoclean" will leave behind anything that it deems a method. For Moose classes, this the based on the "get_method_list" method on from the Class::MOP::Class. For non-Moose classes, anything defined within the package will be identified as a method. This should match Moose's definition of a method. Additionally, the magic subs installed by overload will not be cleaned.

-also => [ ITEM | REGEX | SUB, .. ]

-also => ITEM

-also => REGEX

-also => SUB

Sometimes you don't want to clean imports only, but also helper functions you're using in your methods. The "-also" switch can be used to declare a list of functions that should be removed additional to any imports:

use namespace::autoclean -also => ['some_function', 'another_function'];

If only one function needs to be additionally cleaned the "-also" switch also accepts a plain string:

use namespace::autoclean -also => 'some_function';

In some situations, you may wish for a more powerful cleaning solution.

The "-also" switch can take a Regex or a CodeRef to match against local function names to clean.

use namespace::autoclean -also => qr/^_/
use namespace::autoclean -also => sub { $_ =~ m{^_} };
use namespace::autoclean -also => [qr/^_/ , qr/^hidden_/ ];
use namespace::autoclean -also => [sub { $_ =~ m/^_/ or $_ =~ m/^hidden/ }, sub { uc($_) == $_ } ];

-except => [ ITEM | REGEX | SUB, .. ]

-except => ITEM

-except => REGEX

-except => SUB

This takes exactly the same options as "-also" except that anything this matches will not be cleaned.

When used with Moo classes, the heuristic used to check for methods won't work correctly for methods from roles consumed at compile time.

package My::Class;
use Moo;
use namespace::autoclean;
# Bad, any consumed methods will be cleaned
BEGIN { with 'Some::Role' }
# Good, methods from role will be maintained
with 'Some::Role';

Additionally, method detection may not work properly in Mouse classes in perls earlier than 5.10.

  • namespace::clean
  • B::Hooks::EndOfScope
  • namespace::sweep
  • Sub::Exporter::ForMethods
  • Sub::Name
  • Sub::Install
  • Test::CleanNamespaces
  • Dist::Zilla::Plugin::Test::CleanNamespaces

Bugs may be submitted through the RT bug tracker (or <>).

There is also a mailing list available for users of this distribution, at

There is also an irc channel available for users of this distribution, at "#moose" on "" <irc://>.

Florian Ragwitz <>

  • Karen Etheridge <>
  • Graham Knop <>
  • Dave Rolsky <>
  • Kent Fredric <>
  • Tomas Doran <>
  • Shawn M Moore <>
  • Felix Ostmann <>
  • Chris Prather <>
  • Andrew Rodland <>

This software is copyright (c) 2009 by Florian Ragwitz.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

2022-05-29 perl v5.36.0